revised ebuild, remove a line not need

gdm-2.4.4.7.ebuild (text/plain), 3.39 KB, created by Mario Vazquez on 2004-02-11 19:18:18 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/gnome-base/gdm/gdm-2.4.4.7.ebuild,v 1.0 2004/02/10 21:12:23 darkcoder Exp $

inherit eutils gnome2

DESCRIPTION="GNOME2 Display Manager"
HOMEPAGE="http://www.jirka.org/gdm.html"

SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~alpha ~hppa ~amd64 ~ia64"
LICENSE="GPL-2"
IUSE="tcpd X xinerama"
SRC_URI="${SRC_URI}
	mirror://gentoo/gentoo-gdm-theme.tar.bz2"
MY_V="`echo ${PV} |cut -b -5`"

RDEPEND=">=sys-libs/pam-0.72
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
	>=x11-libs/gtk+-2
	>=gnome-base/libglade-2
	>=gnome-base/librsvg-2
	>=dev-libs/libxml2-2.4.12
	>=gnome-base/libgnome-2
	>=gnome-base/libgnomeui-2
	>=gnome-base/libgnomecanvas-2
	virtual/x11"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=app-text/scrollkeeper-0.3.11
	X? ( virtual/x11
		xinerama? ( virtual/x11 ) )"

G2CONF="${G2CONF} \
	--sysconfdir=/etc/X11 \
	--with-pam-prefix=/etc \
	--with-xdmcp \
	`use_with tcpd tcp-wrappers` \
	`use_with xinerama`"

src_unpack() {
	unpack ${A}

	cd ${S}/daemon
	cp gdm.h gdm.h.orig
	sed -e "s:/usr/bin/X11:/usr/X11R6/bin:g" \
		gdm.h.orig > gdm.h
	rm -f gdm.h.orig

	# Make Gentoo theme default
	cd ${S}/config
	cp gdm.conf.in gdm.conf.in.orig
	sed -e "s:/usr/bin/X11:/usr/X11R6/bin:g" \
		-e "s:#GraphicalTheme=circles:GraphicalTheme=gentoo-emergence:" \
		-e "s:command=/usr/X11R6/bin/X:command=/usr/X11R6/bin/X -nolisten tcp:" \
		gdm.conf.in.orig > gdm.conf.in

	rm -f gdm.conf.in.orig
}

src_install() {

	gnome2_src_install PAM_PREFIX=${D}/etc sysconfdir=${D}/etc/X11

	# gdm-binary should be gdm to work with our init (#5598)
	rm -f ${D}/usr/bin/gdm
	cp ${D}/usr/bin/gdm-binary ${D}/usr/bin/gdm

	# log, etc.
	dodir /var/lib/gdm
	chown gdm:gdm ${D}/var/lib/gdm
	chmod 750 ${D}/var/lib/gdm

	# use our own session script
	rm -f ${D}/etc/X11/gdm/Xsession
	exeinto /etc/X11/gdm
	doexe ${FILESDIR}/${MY_V}/Xsession

	# We replace the pam stuff by our own
	rm -f ${D}/etc/pam.d/gdm

	# pam startup
	dodir /etc/pam.d
	insinto /etc/pam.d
	doins ${FILESDIR}/${MY_V}/pam.d/gdm
	doins ${FILESDIR}/${MY_V}/pam.d/gdmconfig
	doins ${FILESDIR}/${MY_V}/pam.d/gdm-autologin

	# pam security
	dodir /etc/security/console.apps
	insinto /etc/security/console.apps
	doins ${FILESDIR}/${MY_V}/security/console.apps/gdmconfig

	# gnomerc
	dodir /etc/X11/gdm
	exeinto /etc/X11/gdm
	doexe ${FILESDIR}/${MY_V}/gnomerc

	cd ${D}/etc/X11/gdm
	for i in Init/Default PostSession/Default PreSession/Default gdm.conf
	do
		cp ${i} ${i}.orig
		sed -e s:/usr/bin/X11:/usr/X11R6/bin:g \
			${i}.orig > ${i}
		rm ${i}.orig
	done

	# use graphical greeter local
	dosed "s:#Greeter=/usr/bin/gdmlogin:Greeter=/usr/bin/gdmgreeter:" /etc/X11/gdm/gdm.conf

	# Move Gentoo theme in
	mv ${WORKDIR}/gentoo-emergence  ${D}/usr/share/gdm/themes

	dodoc ABOUT-NLS AUTHORS COPYING ChangeLog INSTALL NEWS README* TODO

}

pkg_postinst() {

	gnome2_pkg_postinst

	# Soft restart, assumes Gentoo defaults for file locations
	FIFOFILE=/var/lib/gdm/.gdminfo
	PIDFILE=/var/run/gdm.pid
	if [ -w ${FIFOFILE} ] ; then
		if [ -f ${PIDFILE} ] ; then
			if [ kill -0 `cat ${PIDFILE}` ] ; then
				(echo;echo SOFT_RESTART) >> ${FIFOFILE}
			fi
		fi
	fi

	einfo "To make GDM start at boot, edit /etc/rc.conf"
	einfo "and then execute 'rc-update add xdm default'."

}

pkg_postrm() {

	gnome2_pkg_postrm

	einfo "To remove GDM from startup please execute"
	einfo "'rc-update del xdm default'"

}