# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

DESCRIPTION="Core sounds for asterisk"
HOMEPAGE="http://www.asterisk.org/"
# Note the prefixes here:
# + default enabled USE flag
# - default disabled USE flag
# ^ automatically installed (doesn't result in a setable USE flag).
LINGUAS="^en fr"
CODECS="alaw g722 g729 ^gsm siren7 siren14 sln16 ulaw wav"

SRC_URI=""
IUSE=""
for c in ${CODECS}; do
	[[ "${c}" = ^* ]] || IUSE+=" ${c#[+-]}"
done
for l in ${LINGUAS}; do
	[[ "${l}" != ^* ]] && IUSE+=" ${l}" && SRC_URI+=" ${l#[+-]}? ("
	for c in ${CODECS}; do
		[[ "${c}" = ^* ]] || SRC_URI+=" ${c#[+-]}? ("
		SRC_URI+=" http://downloads.asterisk.org/pub/telephony/sounds/releases/${PN}-${l#[+-^]}-${c#[+-^]}-${PV}.tar.gz"
		[[ "${c}" = ^* ]] || SRC_URI+=" )"
	done
	[[ "${l}" = ^* ]] || SRC_URI+=" )"
done

LICENSE="CCPL-Attribution-ShareAlike-3.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND=">=net-misc/asterisk-1.6.1"

S="${WORKDIR}"

src_unpack() {
	local has_once_codec=
	local has_once_lingua=

	for ar in ${A}; do
		l="${ar#${PN}-}"
		l=${l%%-*}
		echo ">>> Unpacking $ar to ${WORKDIR}/${l}"
		[ -d "${WORKDIR}/${l}" ] || mkdir "${WORKDIR}/${l}" || die "Error creating unpack directory"
		tar xf "${DISTDIR}/${ar}" -C "${WORKDIR}/${l}" || die "Error unpacking ${ar}"
	done
}

src_install() {
	for l in ${LINGUAS}; do
		if [[ "${l}" = ^* ]] || use ${l#[+-]}; then
			l="${l#[+-^]}"
			dodoc ${l}/CHANGES-${PN%-sounds}-${l}-${PV} ${l}/${PN#asterisk-}-${l}.txt
			rm ${l}/CHANGES-${PN%-sounds}-${l}-${PV} ${l}/${PN#asterisk-}-${l}.txt
		fi
	done

	diropts -m 0770 -o asterisk -g asterisk
	insopts -m 0660 -o asterisk -g asterisk

	dodir /var/lib/asterisk/sounds
	insinto /var/lib/asterisk/sounds
	doins -r .
}