dev-util/eclipse-sdk/eclipse-sdk-3.5.2.ebuild

eclipse-sdk-3.5.2.ebuild (text/plain), 12.10 KB, created by Matt Whitlock on 2010-07-17 18:02:20 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$

EAPI="2"
WANT_ANT_TASKS="ant-nodeps"

# eclipse-build is too complicated for automatic fixing
# if there are any fixes we should create patches
# and push them upstream
JAVA_PKG_BSFIX="off"

inherit java-pkg-2 java-ant-2 check-reqs

BUILD_ID="3.5.2"
ECLIPSE_BUILD_VER="0.5.0"
S="${WORKDIR}/eclipse-build-${ECLIPSE_BUILD_VER}"

DESCRIPTION="Eclipse SDK"
HOMEPAGE="http://www.eclipse.org/eclipse/"
SRC_URI="http://download.eclipse.org/technology/linuxtools/eclipse-build/eclipse-${BUILD_ID}-src.tar.bz2
	http://download.eclipse.org/technology/linuxtools/eclipse-build/eclipse-build-${ECLIPSE_BUILD_VER}.tar.bz2"

LICENSE="EPL-1.0"
SLOT="3.5"
KEYWORDS="~amd64 ~x86"
IUSE="doc gnome source"

CDEPEND=">=dev-java/swt-${PV}:${SLOT}
	>=dev-java/ant-1.7.1
	>=dev-java/asm-3.1:3
	>=dev-java/commons-codec-1.3
	>=dev-java/commons-el-1.0
	>=dev-java/commons-httpclient-3.1:3
	>=dev-java/commons-logging-1.0.4
	>=dev-java/hamcrest-core-1.1
	>=dev-java/icu4j-4.0.1:4
	>=dev-java/jsch-0.1.41
	>=dev-java/junit-3.8.2:0
	>=dev-java/junit-4.5:4
	>=dev-java/lucene-1.9.1:1.9
	>=dev-java/lucene-analyzers-1.9.1:1.9
	>=dev-java/sat4j-core-2.1.1:2
	>=dev-java/sat4j-pseudo-2.1.1:2
	dev-java/tomcat-servlet-api:2.5
	>=www-servers/jetty-6.1.15:6
	>=www-servers/tomcat-5.5.17:5.5
	x86? ( gnome? ( gnome-base/gconf ) )"
RDEPEND="${CDEPEND}
	>=virtual/jre-1.5"
DEPEND="${CDEPEND}
	app-arch/unzip
	app-arch/zip
	>=dev-java/ant-antlr-1.7.1
	>=dev-java/ant-apache-bcel-1.7.1
	>=dev-java/ant-apache-bsf-1.7.1
	>=dev-java/ant-apache-log4j-1.7.1
	>=dev-java/ant-apache-oro-1.7.1
	>=dev-java/ant-apache-regexp-1.7.1
	>=dev-java/ant-apache-resolver-1.7.1
	>=dev-java/ant-commons-logging-1.7.1
	>=dev-java/ant-commons-net-1.7.1
	>=dev-java/ant-core-1.7.1
	>=dev-java/ant-javamail-1.7.1
	>=dev-java/ant-jdepend-1.7.1
	>=dev-java/ant-jsch-1.7.1
	>=dev-java/ant-junit-1.7.1
	>=dev-java/ant-nodeps-1.7.1
	>=dev-java/ant-swing-1.7.1
	>=dev-java/ant-trax-1.7.1
	>=virtual/jdk-1.6"

ALL_OS='aix hpux linux macosx qnx solaris win32'
ALL_WS='carbon cocoa gtk motif photon win32 wpf'
ALL_ARCH='alpha arm ia64 mips mipsel PA_RISC ppc ppc64 s390 s390x sparc sparc64 x86 x86_64'

buildDir="${S}/build/eclipse-${BUILD_ID}-src"

pkg_setup() {
	ws='gtk'
	if use x86 ; then os='linux' ; arch='x86'
	elif use amd64 ; then os='linux' ; arch='x86_64'
	fi

	java-pkg-2_pkg_setup

	if use doc ; then
		ewarn "Having the 'doc' USE flag enabled greatly increases the build time."
		ewarn "You might want to disable it for ${PN} if you don't need it."
	fi
}

src_unpack() {
	CHECKREQS_MEMORY="1536"
	if use doc ; then
		CHECKREQS_DISK_BUILD="3072"
	else
		CHECKREQS_DISK_BUILD="1536"
	fi
	check_reqs

	unpack "eclipse-build-${ECLIPSE_BUILD_VER}.tar.bz2"
	ln -s "${DISTDIR}/eclipse-${BUILD_ID}-src.tar.bz2" "${S}"/ || die

	cd "${S}"
	# building with ecj fails for some reason (polluted classpath probably)
	java-pkg_force-compiler javac
	eant unpack
}

src_prepare() {
	# set buildArch if we're x86_64
	if use amd64 ; then
		sed -e 's/^\(buildArch=\).*$/\1x86_64/' -i build.properties || die
	fi

	# apply patches before we start cleaning junk out
	eant applyPatches

	# fix up hardcoded runtime class paths
	sed -e 's|/usr/lib/jvm/java/jre/lib/rt\.jar:.*$|'"$(java-config --runtime)"'|' \
			-i {,pde}build.properties || die

	# we'll handle our own dependency symlinking, so disable eclipse-build helper
	sed -e 's/,symlinkDeps,/,/' -i build.xml || die
	sed_xml_element 'target' -e '/name="provision.sdk"/ s|<symlinkInstalled.*\(<echo \)|\1|' \
			-i build.xml || die

	# disable building of libgnomeproxy on x86 if USE=-gnome
	if ! use gnome ; then
		sed_xml_element 'condition' -e '/property="build\.libgnomeproxy"/d' -i build.xml || die
	fi

	# skip compilation of SWT native libraries (we use the system-installed copies)
	sed_xml_element 'ant' -e '/swt/d' -i build.xml || die

	ebegin 'Removing plugins of irrelevant platforms'
	local remove_os=" ${ALL_OS} " ; remove_os=${remove_os/ ${os} / }
	remove_os=${remove_os# } ; remove_os=${remove_os% } ; remove_os=${remove_os// /'\|'}
	local remove_ws=" ${ALL_WS} " ; remove_ws=${remove_ws/ ${ws} / }
	remove_ws=${remove_ws# } ; remove_ws=${remove_ws% } ; remove_ws=${remove_ws// /'\|'}
	local remove_arch=" ${ALL_ARCH} " ; remove_arch=${remove_arch/ ${arch} / }
	remove_arch=${remove_arch# } ; remove_arch=${remove_arch% } ; remove_arch=${remove_arch// /'\|'}
	sed_xml_element 'includes\|plugin' \
			-e '/id="org\.eclipse\.\(core\.net\.linux\.x86\|update\.core\.linux\)"/b' \
			-e '/os="'"${remove_os}"'"/d' -e '/ws="'"${remove_ws}"'"/d' -e '/arch="'"${remove_arch}"'"/d' \
			-i "${buildDir}"/features/*/feature.xml "${S}"/eclipse-build-feature/feature.xml \
		|| die 'remove irrelevant platforms failed'
	eend

	if ! use doc ; then
		ebegin 'Removing documentation plugins'
		rm -rf "${buildDir}"/plugins/*.doc{,.*}
		eclipse_delete-plugins '.*\.doc\(\..*\|\)'
		eend
	fi

	if ! use source ; then
		ebegin 'Removing source plugins'
		rm -rf "${buildDir}"/plugins/*.source{,_*}
		eclipse_delete-plugins '.*\.source'
		eend
	fi

	ebegin 'Linking dependencies'
	eclipse_create-osgi-dep com.ibm.icu icu4j-4
	eclipse_create-osgi-dep com.jcraft.jsch jsch
	eclipse_create-osgi-dep javax.servlet tomcat-servlet-api-2.5 servlet-api
	eclipse_create-osgi-dep javax.servlet.jsp tomcat-servlet-api-2.5 jsp-api
	eclipse_create-osgi-dep org.apache.commons.codec commons-codec
	eclipse_create-osgi-dep org.apache.commons.el commons-el
	eclipse_create-osgi-dep org.apache.commons.httpclient commons-httpclient-3
	eclipse_create-osgi-dep org.apache.commons.logging commons-logging
	eclipse_create-osgi-dep org.apache.jasper tomcat-5.5 jasper-compiler jasper-runtime
	eclipse_create-osgi-dep org.apache.lucene lucene-1.9
	eclipse_create-osgi-dep org.apache.lucene.analysis lucene-analyzers-1.9
	eclipse_create-osgi-dep org.hamcrest.core hamcrest-core
	eclipse_create-osgi-dep org.mortbay.jetty.server jetty-6 jetty
	eclipse_create-osgi-dep org.mortbay.jetty.util jetty-6 jetty-util
	eclipse_create-osgi-dep org.objectweb.asm asm-3
	eclipse_create-osgi-dep org.sat4j.core sat4j-core-2
	eclipse_create-osgi-dep org.sat4j.pb sat4j-pseudo-2
	eclipse_create-nonosgi-dep org.apache.ant ant-antlr
	eclipse_create-nonosgi-dep org.apache.ant ant-apache-bcel
	eclipse_create-nonosgi-dep org.apache.ant ant-apache-bsf
	eclipse_create-nonosgi-dep org.apache.ant ant-apache-log4j
	eclipse_create-nonosgi-dep org.apache.ant ant-apache-oro
	eclipse_create-nonosgi-dep org.apache.ant ant-apache-regexp
	eclipse_create-nonosgi-dep org.apache.ant ant-apache-resolver
	eclipse_create-nonosgi-dep org.apache.ant ant-commons-logging
	eclipse_create-nonosgi-dep org.apache.ant ant-commons-net
	eclipse_create-nonosgi-dep org.apache.ant ant-core ant ant-launcher
	eclipse_create-nonosgi-dep org.apache.ant ant-javamail
	eclipse_create-nonosgi-dep org.apache.ant ant-jdepend
	eclipse_create-nonosgi-dep org.apache.ant ant-jsch
	eclipse_create-nonosgi-dep org.apache.ant ant-junit
	eclipse_create-nonosgi-dep org.apache.ant ant-nodeps
	eclipse_create-nonosgi-dep org.apache.ant ant-swing
	eclipse_create-nonosgi-dep org.apache.ant ant-trax
	eclipse_create-nonosgi-dep org.junit junit
	eclipse_create-nonosgi-dep org.junit4 junit-4 junit
	eend

	cd "${buildDir}" || die
	epatch "${FILESDIR}/${SLOT}/hamcrest-junit-lib.patch"
	epatch "${FILESDIR}/${SLOT}/gtk_makefile.patch"
}

src_compile() {
	ANT_OPTS='-Xmx512M' eant -DbuildArch="${arch}"
}

src_install() {
	local destDir="/usr/$(get_libdir)/eclipse-${SLOT}"

	insinto "${destDir}"
	shopt -s dotglob
	doins -r "${buildDir}"/installation/* || die
	shopt -u dotglob
	chmod +x "${D}${destDir}"/eclipse
	rm -f "${D}${destDir}"/libcairo-swt.so  # use the system-installed SWT libraries

	# redo symlinks
	pushd "${buildDir}" > /dev/null || die
	find plugins -type l | while read -r link ; do
		if [[ -e installation/${link} ]] ; then
			cp -d "${link}" "${D}${destDir}/${link}" || die
		else
			cp -d "${link}" "${D}${destDir}/$(dirname "${link}")_"*"/$(basename "${link}")" || die
		fi
	done
	popd > /dev/null || die

	# Install Gentoo wrapper and config
	dobin "${FILESDIR}/${SLOT}/eclipse-${SLOT}" || die
	insinto /etc
	doins "${FILESDIR}/${SLOT}/eclipserc-${SLOT}" || die

	# Create desktop entry
	make_desktop_entry "eclipse-${SLOT}" "Eclipse ${PV}" "${destDir}/icon.xpm" || die
}

eclipse_create-osgi-dep() {
	local bundle=${1} package=${2} ; shift 2
	bundle=$(basename "${S}/dependencyManifests/${bundle}"_*.jar .jar) || die
	einfo "  ${bundle} => ${package}" "${@}"
	mkdir -p "${buildDir}/plugins/${bundle}" || die
	pushd "${buildDir}/plugins/${bundle}" > /dev/null || die
	if (( ${#} )) ; then
		local jar ; for jar in "${@}" ; do
			java-pkg_jar-from "${package}" "${jar}.jar"
		done
	else
		java-pkg_jar-from "${package}"
	fi
	mkdir META-INF || die
	cp "${S}/dependencyManifests/${bundle}.jar/META-INF/MANIFEST.MF" META-INF/ || die
	manifest_replace META-INF/MANIFEST.MF 'Bundle-ClassPath' "$(echo *.jar | tr ' ' ',')"
	manifest_delete META-INF/MANIFEST.MF 'Name\|SHA1-Digest'
	# replace classpath refs to this bundle with refs to system-installed jars
	sed_xml_element 'pathelement' -e '/path="\([^"]\+\/\)\?'"${bundle//./\.}"'\.jar"/c '"$(
			for jar in *.jar ; do
				echo -n '<pathelement path="'"$(readlink "${jar}")"'"/>'
			done)" -i "${buildDir}"/plugins/*/build.xml || die
	popd > /dev/null || die
	# include unpacked bundle in copy to bootstrap plugins dir
	sed_xml_element 'fileset' -e '/id="orbitDeps"/ s|</fileset>|<include name="'"${bundle}/"'"/>\0|' \
			-i "${S}/pdebuild.xml" || die
}

eclipse_create-nonosgi-dep() {
	local bundle=${1} package=${2} ; shift 2
	local pdir=${buildDir}/plugins
	local jar ; for jar in "${@:-${package}}" ; do
		local dir=$(dirname "$(grep -o "${bundle//./\.}"'\(_[^/=]*\)\?/\([^/=]*/\)*'"${jar}"'\.jar' \
				"${S}/nonosgidependencies.properties")") || die
		einfo "  ${dir}/${jar}.jar => ${package}"
		mkdir -p "${pdir}/${dir}" || die
		java-pkg_jar-from "${package}" "${jar}.jar" "${pdir}/${dir}/${jar}.jar"
		dir=${dir%%/*}
		manifest_delete "${pdir}/${dir}/META-INF/MANIFEST.MF" 'Name\|SHA1-Digest'
		rm -f "${pdir}/${dir}"/META-INF/ECLIPSEF.{RSA,SF}
	done
}

# Removes feature.xml references to plugins matching ${1}.
eclipse_delete-plugins() {
	sed_xml_element 'includes\|plugin' -e '/id="'"${1}"'"/d' \
			-i "${buildDir}"/features/*/feature.xml "${S}"/eclipse-build-feature/feature.xml \
		|| die 'eclipse_delete-plugins failed'
}

# Prints the first value from manifest file ${1} whose key matches regex ${2},
# unfolding as necessary.
manifest_get() {
	sed -n -e '/^\('"${2}"'\): /{h;:A;$bB;n;/^ /!bB;H;bA};d;:B;g;s/^[^:]*: //;s/\n //g;p;q' "${1}" \
		|| die 'manifest_get failed'
}

# Deletes values from manifest file ${1} whose keys match regex ${2}, taking
# into account folding.
manifest_delete() {
	sed -n -e ':A;/^\('"${2}"'\): /{:B;n;/^ /!{bA};bB};p' -i "${1}" \
		|| die 'manifest_delete failed'
}

# Replaces the value for key ${2} in the first section of manifest file ${1}
# with ${3}, or adds the key-value pair to that section if the key was absent.
manifest_replace() {
	LC_ALL='C' awk -v key="${2}" -v val="${3}" '
function fold(s,  o, l, r) {
	o = 2 ; l = length(s) - 1 ; r = substr(s, 1, 1)
	while (l > 69) { r = r substr(s, o, 69) "\n " ; o += 69 ; l -= 69 }
	return r substr(s, o)
}
BEGIN { FS = ": " }
f { print ; next }
i { if ($0 !~ "^ ") { f = 1 ; print } ; next }
$1 == key { print fold(key FS val) ; i = 1 ; next }
/^\r?$/ { print fold(key FS val) ; print ; f = 1 ; next }
{ print }
END { if (!f) { print fold(key FS val) } }
' "${1}" > "${1}-" && mv "${1}"{-,} || die 'manifest_replace failed'
}

# Executes sed over each XML element with a name matching ${1}, rather than
# over each line. The entire element (and its children) may be removed with the
# 'd' command, or they may be edited using all the usual sed foo. Basically,
# the script argument will be executed only for elements matching ${1}, and the
# sed pattern space will consist of the entire element, including any nested
# elements. Note that this is not perfect and requires no more than one XML
# element per line to be reliable.
sed_xml_element() {
	local elem=${1} ; shift
	sed -e '/<\('"${elem}"'\)\([> \t]\|$\)/{:_1;/>/!{N;b_1};/\/>/b_3' \
			-e ':_2;/<\/\('"${elem}"'\)>/!{N;b_2};b_3};b;:_3' "${@}"
}