# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License, v2 or later
# $Header:$

inherit games eutils

TARGET=mame
TARGET_VER=0.77.2
DESCRIPTION="Frontend for AdvanceMAME, MAME, MESS, RAINE and any other emulator"
HOMEPAGE="http://advancemame.sourceforge.net/menu-readme.html"
SRC_URI="mirror://sourceforge/advancemame/${P}.tar.gz
	mirror://sourceforge/advancemame/advance${TARGET}-${TARGET_VER}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc"
IUSE="debug static svga alsa oss slang sdl"

RDEPEND="virtual/glibc
	~games-emulation/advance${TARGET}-${TARGET_VER}
	sys-libs/zlib
	x86? ( >=dev-lang/nasm-0.98 )
	sdl? ( media-libs/libsdl )
	slang? ( sys-libs/slang )
	alsa? ( media-libs/alsa-lib )
	svga? ( >=media-libs/svgalib-1.9 )"
DEPEND="${RDEPEND}
	fbcon? ( virtual/os-headers )"

src_unpack() {
	mkdir ${S}
	unpack advance${TARGET}-${TARGET_VER}.tar.gz
	mv advance${TARGET}-${TARGET_VER}/* ${S}/
	unpack ${P}.tar.gz
}

src_compile() {
	export PATH="${PATH}:${T}"
	ln -s `which nasm` ${T}/${CHOST}-nasm
	use sdl && ln -s `which sdl-config` ${T}/${CHOST}-sdl-config
	egamesconf \
		`use_enable debug` \
		`use_enable static` \
		`use_enable x86 asm` \
		`use_enable svga svgalib` \
		`use_enable fbcon fb` \
		`use_enable alsa` \
		`use_enable oss` \
		`use_enable slang` \
		`use_enable sdl` \
		--with-emu=${TARGET} \
		|| die
	emake || die
}

src_install() {
	newgamesbin advmenu advmenu-${TARGET}
	dodoc HISTORY README RELEASE obj/doc/*.txt
	dohtml obj/doc/*.html
	prepgamesdirs
}