ebuild, works fine for me

cgit-0.8.3.2.ebuild (text/plain), 1.57 KB, created by Nikoli on 2010-06-24 21:27:16 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit webapp eutils

[[ -z "${CGIT_CACHEDIR}" ]] && CGIT_CACHEDIR="/var/cache/${PN}/"
# Webserver group, here for Apache by default
HTTPD_GROUP="${HTTPD_GROUP:-apache}"

GIT_V="1.7.0"

DESCRIPTION="a fast web-interface for git repositories"
HOMEPAGE="http://hjemli.net/git/cgit/about/"
SRC_URI="mirror://kernel/software/scm/git/git-${GIT_V}.tar.bz2
	http://hjemli.net/git/cgit/snapshot/${P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

RDEPEND="
	dev-vcs/git
	sys-libs/zlib
	dev-libs/openssl
	virtual/httpd-cgi
"
DEPEND="${RDEPEND}
	doc? ( app-text/docbook-xsl-stylesheets
		>=app-text/asciidoc-8.5.1 )
"

pkg_setup() {
	webapp_pkg_setup

	ebegin "Creating ${PN} user"
	enewuser "${PN}"
	eend ${?}
}

src_prepare() {
	rmdir git
	mv "${WORKDIR}"/git-"${GIT_V}" git

	sed -i \
		-e "/^CACHE_ROOT =/s:/var/cache/cgit:${CGIT_CACHEDIR}:" \
		Makefile || die "sed failed"
}

src_compile() {
	emake || die "emake failed"
	if use doc ; then
		emake man-doc || die "emake man-doc died"
	fi
}

src_install() {
	webapp_src_preinst

	emake \
		CGIT_SCRIPT_PATH="${MY_CGIBINDIR}" \
		CGIT_DATA_PATH="${MY_HTDOCSDIR}" \
		DESTDIR="${D}" install || die "emake install failed"

	insinto /etc
	doins "${FILESDIR}"/cgitrc

	dodoc README
	use doc && doman cgitrc.5

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_src_install

	dodir "${CGIT_CACHEDIR}"
	keepdir "${CGIT_CACHEDIR}"
	fowners ${PN}:${HTTPD_GROUP} "${CGIT_CACHEDIR}"
	fperms 750 "${CGIT_CACHEDIR}"
}