Updated ebuild for GLUI

glui-2.1_beta-r3.ebuild (text/plain), 1.71 KB, created by Daniel Westermann-Clark on 2004-01-08 20:04:26 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $
# Initial ebuild from steven knight <[e-mail]>, in bug 23207
# Updated by Daniel Westermann-Clark <[e-mail]>

inherit libtool

# The upstream tarball uses a poor naming convention
MY_P=${PN}_v${PV/./_}
MY_PV=${PV/_beta/}
DESCRIPTION="GLUI is a GLUT-based C++ user interface library"
SRC_URI="http://www.cs.unc.edu/~rademach/glui/src/release/${MY_P}.tar.gz"

# Set the source directory, since the upstream tarball uses a poor naming
# convention
S=${WORKDIR}/${MY_P}

# This patch is based on:
# http://http.us.debian.org/debian/pool/main/g/glui/glui_2.1.0.beta-2.diff.gz
#
# Removed the Debian-specific files; removed the broken upstream Makefiles;
# removed the explicit setting of CC, CXX, CFLAGS, CXXFLAGS, and LDFLAGS;
# and added building of the shared library
GLUI_DEBIAN_PATCH="glui-2.1_beta-r3-debian.diff"

SLOT="0"

LICENSE="LGPL-2"
KEYWORDS="-* ~x86"

DEPEND="virtual/opengl
	virtual/glut"


src_unpack() { 
	unpack ${A}
	epatch ${FILESDIR}/${GLUI_DEBIAN_PATCH} || die "epatch failed"
}

src_compile() {
	emake || die "emake failed"
}

src_install() {
	# This doesn't use einstall, since the Makefile does not have an install
	# target
	dolib.a *.a

	dolib.so libglui.so.${MY_PV}
	dosym libglui.so.${MY_PV} /usr/lib/libglui.so.${MY_PV/.1/}
	dosym libglui.so.${MY_PV} /usr/lib/libglui.so

	insinto /usr/include/GL
	doins glui.h

	newdoc readme.txt README
}

pkg_postinst() {
	einfo "To use this library, link using -lglui and include /usr/include/GL/glui.h"
        einfo
	einfo "Note: Examples are not included in this release, pending the creation of"
        einfo "an updated Makefile"
}