# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit eutils versionator base cmake-utils

MY_PN="OpenSceneGraph"
MY_P=${MY_PN}-${PV}

DESCRIPTION="Open source high performance 3D graphics toolkit"
HOMEPAGE="http://www.openscenegraph.org/projects/osg/"
SRC_URI="http://www.openscenegraph.org/downloads/stable_releases/${MY_P}/source/${MY_P}.zip"

LICENSE="wxWinLL-3 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="curl ffmpeg gif jpeg jpeg2k osgapps pdf png svg tiff truetype xine xrandr xulrunner"

RDEPEND="virtual/glu
	virtual/opengl
	x11-libs/libSM
	x11-libs/libXext
	curl? ( net-misc/curl )
	ffmpeg? ( media-video/ffmpeg )
	gif? ( media-libs/giflib )
	jpeg2k? ( media-libs/jasper )
	jpeg? ( media-libs/jpeg )
	pdf? ( app-text/poppler[cairo] )
	png? ( media-libs/libpng )
	svg? ( gnome-base/librsvg )
	tiff? ( media-libs/tiff )
	truetype? ( media-libs/freetype:2 )
	xine? ( media-libs/xine-lib )
	xrandr? ( x11-libs/libXrandr )
	xulrunner? ( net-libs/xulrunner:1.8 )"
DEPEND="${RDEPEND}
	app-arch/unzip
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}

DOCS="AUTHORS.txt ChangeLog NEWS.txt"

PATCHES=(
	"${FILESDIR}"/${P}-magicoff.patch
)

src_configure() {
	mycmakeargs="
		$(cmake-utils_use_build osgapps OSG_APPLICATIONS)
		$(cmake-utils_use_enable xulrunner XUL)
		$(cmake-utils_use_enable pdf)
		$(cmake-utils_use_enable xine)
		$(cmake-utils_use_enable jpeg2k JPEG2K)
		$(cmake-utils_use_enable svg)
		$(cmake-utils_use_enable truetype FREETYPE)
		$(cmake-utils_use_enable curl)
		$(cmake-utils_use_enable gif)
		$(cmake-utils_use_enable png)
		$(cmake-utils_use_enable jpeg)
		$(cmake-utils_use_enable tiff)
		$(cmake-utils_use_enable xrandr)
		$(cmake-utils_use_enable ffmpeg)
	"
	cmake-utils_src_configure
}