games-fps/postal2mp-1409.ebuild

postal2mp-1409.ebuild (text/plain), 1.40 KB, created by Laurento Frittella (mrfree) on 2010-05-10 09:50:03 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit eutils multilib games

DESCRIPTION="Postal 2: Share the Pain - Free Multiplayer Edition"
HOMEPAGE="http://icculus.org/news/news.php?id=4419"
SRC_URI="http://0day.icculus.org/postal2/Postal2STP-FreeMP-linux.tar.bz2
	http://treefort.icculus.org/postal2/Postal2STP-FreeMP-linux.tar.bz2
	http://cyberstalker.dk/sponsored-by-dkchan.org/Postal2STP-FreeMP-linux.tar.bz2"

LICENSE="postal2stp-freemp"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
RESTRICT="mirror strip"
PROPERTIES="interactive"

RDEPEND="virtual/opengl
	sys-libs/glibc
	amd64? ( app-emulation/emul-linux-x86-sdl )
	x86? (
		media-libs/libsdl[X,opengl]
		media-libs/openal
	)"
DEPEND=""

S=${WORKDIR}/Postal2STP-FreeMP-linux

GAMES_CHECK_LICENSE="yes"

src_install() {
	has_multilib_profile && ABI=x86

	dir=${GAMES_PREFIX_OPT}/${PN}

	insinto "${dir}"
	doins -r Animations KarmaData Maps Music Sounds \
		 StaticMeshes System Textures Web || die "doins failed"
	fperms +x "${dir}"/System/postal2-bin || die "fperms failed"

	dosym /usr/$(get_libdir)/libopenal.so "${dir}"/System/openal.so || die
	dosym /usr/$(get_libdir)/libSDL-1.2.so.0 "${dir}"/System/libSDL-1.2.so.0 || die

	games_make_wrapper ${PN} ./postal2-bin "${dir}"/System .
	newicon postal2.xpm ${PN}.xpm
	make_desktop_entry ${PN} "Postal 2 (Free MultiPlayer Ed.)"

	prepgamesdirs
}