# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils games toolchain-funcs

DESCRIPTION="Hollywood tactical shooter based on the ioquake3 engine"
HOMEPAGE="http://www.urbanterror.net/
	  http://www.www0.org/w/Optimized_executable;_builds_of_ioq3_engine_for_urt"
SRC_URI="http://www0.org/urt/ioq3-1779-urt-git-170310.tar.7z
	http://urt.hsogaming.com/mirror/currentversion/UrbanTerror_${PV/./}_FULL.zip
	ftp://ftp.snt.utwente.nl/pub/games/${PN}/UrbanTerror_${PV/./}_FULL.zip"
# maybe http://www0.org/urt/ioq3-1783-urt-git-240410.tar.7z
# maybe PV set to 4.1.1738

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+client +curl openal server speex vorbis"

COMMON_DEPEND="
	client? (
		media-libs/libsdl[X,opengl]
		openal? ( media-libs/openal )
		vorbis? ( media-libs/libogg media-libs/libvorbis )
	)
	curl? ( net-misc/curl )
	speex? ( media-libs/speex ) "
DEPEND="${COMMON_DEPEND}
	app-arch/p7zip
	app-arch/unzip
	dev-util/pkgconfig"
RDEPEND="${COMMON_DEPEND}"

S=${WORKDIR}/ioq3-urt-git/ioq3-urt

src_unpack() {
	unpack ${A}
	unpack ./ioq3-urt-git.tar
}

src_prepare() {
	epatch "${FILESDIR}/portability.diff"

	# fix case sensitivity
	local my_dir=${WORKDIR}/UrbanTerror/q3ut4/demos
	mv "${my_dir}/tutorial.dm_68" "${my_dir}/TUTORIAL.dm_68" || die

	rm -f "${WORKDIR}"/UrbanTerror/io{UrbanTerror,UrTded,}.{exe,i386,x86_64} || die

	#einfo "remove bundled include files"
	#rm -rf code/{AL,SDL12,jpeg-6b,libcurl,libs/win{32,64},zlib} || die
}

src_compile() {
	buildit() { use $1 && echo 1 || echo 0 ; }

	emake \
		$(use amd64 && echo ARCH=x86_64 || echo ARCH=i386) \
		BUILD_SERVER=$(buildit server) \
		BUILD_CLIENT=$(buildit client) \
		BUILD_CLIENT_SMP=$(buildit client) \
		CC="$(tc-getCC)" \
		DEFAULT_BASEDIR="${GAMES_DATADIR}/${PN}" \
		USE_CODEC_VORBIS=$(buildit vorbis) \
		USE_OPENAL=$(buildit openal) \
		USE_CURL=$(buildit curl) \
		USE_VOIP=$(buildit speex) \
		USE_INTERNAL_SPEEX=0 \
		USE_INTERNAL_ZLIB=0 \
		USE_LOCAL_HEADERS=0 \
		release || die
	#BASE_CFLAGS="${CFLAGS} -DUSE_ICON -DPRODUCT_VERSION=\\\"$(VERSION)\\\"" \
}

src_install() {
	local my_arch=x86
	use amd64 && my_arch=x86_64

	if use client ; then
		newgamesbin build/release-linux-${my_arch}/ioquake3-smp.${my_arch} ${PN} || die
		make_desktop_entry ${PN} "UrbanTerror" ${PN}
	fi

	if use server ; then
			newgamesbin build/release-linux-${my_arch}/ioquake3-smp.${my_arch} ${PN}-dedicated || die
			make_desktop_entry ${PN}-dedicated "UrbanTerror dedicated" ${PN}

			insinto "${GAMES_DATADIR}"/${PN}/q3ut4
			doins dedicated.cfg || die
	fi

	dodoc ChangeLog NOTTODO README TODO {md4,voip}-readme.txt || die

	cd "${WORKDIR}"/UrbanTerror/q3ut4 || die

	insinto /usr/share/pixmaps
	newins q3ut.ico ${PN}.ico || die

	insinto "${GAMES_DATADIR}"/${PN}/q3ut4
	doins -r *.pk3 autoexec.cfg demos/ description.txt mapcycle.txt screenshots/ || die

	prepgamesdirs
}