ebuild for net-misc/tinc-1.0.13 with IUSE="+lzo +zlib"

tinc-1.0.13.ebuild (text/plain), 1.09 KB, created by Jan Psota on 2010-04-11 19:58:19 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tinc/tinc-1.0.13.ebuild,v 1.1 2010/04/11 21:11:55 jasiu Exp $

EAPI=2

DESCRIPTION="tinc is an easy to configure VPN implementation"
HOMEPAGE="http://www.tinc-vpn.org/"
SRC_URI="http://www.tinc-vpn.org/packages/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86 ~x86-linux ~ppc-macos ~x86-macos"
IUSE="+lzo +zlib"

DEPEND=">=dev-libs/openssl-0.9.8n
	lzo? ( dev-libs/lzo:2 )
	zlib? ( >=sys-libs/zlib-1.2.3-r1 )
	kernel_linux? ( virtual/linux-sources )"

src_configure() {
	econf $(use_enable lzo) $(use_enable zlib) --enable-jumbograms
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodir /etc/tinc

	gunzip doc/sample-config.tar.gz
	dodoc AUTHORS NEWS README THANKS doc/sample-config.tar

	cd "${FILESDIR}"
	doinitd tincd{,.lo}
	doconfd tinc.networks
	newconfd tincd.conf tincd
}

pkg_postinst() {
	elog "This package requires the tun/tap kernel device."
	elog "Look at http://www.tinc-vpn.org/ for how to configure tinc"
}