allegro-4.4.1.1.ebuild

allegro-4.4.1.1.ebuild (text/plain), 2.07 KB, created by Samuli Suominen (RETIRED) on 2010-03-15 20:00:12 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/allegro-4.2.2-r1.ebuild,v 1.11 2009/11/11 06:59:44 mr_bones_ Exp $

EAPI=2
inherit cmake-utils

DESCRIPTION="cross-platform multimedia library"
HOMEPAGE="http://alleg.sourceforge.net/"
SRC_URI="mirror://sourceforge/alleg/${P}.tar.gz"

LICENSE="Allegro as-is GPL-2 ZLIB"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="examples fbcon jpeg opengl png svga test vga vorbis X"

RDEPEND="media-libs/alsa-lib
	media-sound/jack-audio-connection-kit
	jpeg? ( >=media-libs/jpeg-6b )
	png? ( >=media-libs/libpng-1.2 )
	svga? ( media-libs/svgalib )
	vorbis? ( media-libs/libvorbis )
	X? (
		x11-libs/libX11
		x11-libs/libXcursor
		x11-libs/libXext
		x11-libs/libXpm
		x11-libs/libXt
		x11-libs/libXxf86dga
		x11-libs/libXxf86vm
		opengl? ( virtual/opengl )
	)
	!media-libs/allegrogl
	!media-libs/jpgalleg"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	X? (
		x11-proto/xextproto
		x11-proto/xf86dgaproto
		x11-proto/xf86vidmodeproto
		x11-proto/xproto
	)"

src_prepare() {
	epatch "${FILESDIR}"/${P}-shared.patch

	sed -i \
		-e 's:-I${includedir}:-I${includedir}/loadpng:' \
		misc/loadpng.pc.in || die
}

src_configure() {
	mycmakeargs=(
		"-DWANT_DOCS=OFF"
		"-DWANT_DOCS_INFO=OFF"
		"-DWANT_DOCS_MAN=OFF"
		$(cmake-utils_use_want examples)
		$(cmake-utils_use_want jpeg JPGALLEG)
		$(cmake-utils_use_want fbcon LINUX_FBCON)
		$(cmake-utils_use_want svga LINUX_SVGALIB)
		$(cmake-utils_use_want vga LINUX_VGA)
		$(cmake-utils_use_want png LOADPNG)
		$(cmake-utils_use_want vorbis LOGG)
		$(cmake-utils_use_want test TESTS)
		$(cmake-utils_use_want X X11)
		)

	if use X; then
		mycmakeargs+=(
			$(cmake-utils_use_want opengl ALLEGROGL)
			)
	else
		mycmakeargs+=(
			"-DWANT_ALLEGROGL=OFF"
			)
	fi

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if use png; then
		dodir /usr/include/loadpng
		mv -vf "${D}"/usr/include/loadpng.h "${D}"/usr/include/loadpng || die
	fi

	dodoc AUTHORS CHANGES readme.txt THANKS todo.txt
}