# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils linux-mod

DESCRIPTION="Driver for the RaLink RT3572 USB wireless chipsets"
HOMEPAGE="http://www.ralinktech.com/support.php?s=2"
LICENSE="GPL-2"

RESTRICT="bindist fetch mirror"

MY_P="RT3572_LinuxSTA"

SRC_URI="${MY_P}_V${PV}.tar.bz2"

KEYWORDS="-* ~amd64 x86"
IUSE="debug"
SLOT="0"

DEPEND=""
RDEPEND="net-wireless/wireless-tools"

S="${WORKDIR}/${MY_P}_V${PV}"
MODULE_NAMES="rt3572sta(net:${S}:${S}/os/linux)"
BUILD_TARGETS=" "
MODULESD_RT3572STA_ALIASES=('ra? rt3572sta')
MODULESD_RT3572STA_ADDITIONS=('blacklist rt2800usb')

CONFIG_CHECK="WIRELESS_EXT"
ERROR_WIRELESS_EXT="${P} requires support for Wireless LAN drivers (non-hamradio) & Wireless Extensions (CONFIG_WIRELESS_EXT)."

pkg_nofetch() {
	elog "Please download the tar.bz2 source named:"
	elog "RT3572USB version 2.3.0.0 from:"
	elog "http://www.ralinktech.com/support.php?s=2"
	elog "Then put the file in ${DISTDIR}/${SRC_URI}"
}

src_compile() {
	epatch ${FILESDIR}/${P}-Makefile.patch
	epatch ${FILESDIR}/${P}-config.mk.patch
	epatch ${FILESDIR}/${P}-rtusb_dev_id.c.patch
	use debug || epatch ${FILESDIR}/${P}-nodebug.patch

	linux-mod_src_compile
}

src_install() {
	linux-mod_src_install

	dodoc README_STA iwpriv_usage.txt
	insinto /etc/Wireless/RT2870STA
	insopts -m 0600
	doins RT2870STA.dat
	doins RT2870STACard.dat
	insinto /$(get_libdir)/firmware
	insopts -m 0644
	doins common/rt2870.bin
}

pkg_postinst() {
	linux-mod_pkg_postinst

	einfo
	einfo "Thanks to RaLink for releasing open drivers!"
	einfo
	einfo "The staging 'rt2800usb' kernel driver has been auto blacklisted."
	einfo "If you want to use it again, blacklist this driver ('rt3572sta')"
	einfo "and allow the 'rt2800usb' one."
	einfo
}