Complete Transmission 1.83 ebuild

transmission-1.83.ebuild (text/plain), 2.58 KB, created by Brad Laue on 2010-02-05 13:56:20 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-1.76.ebuild,v 1.3 2009/12/29 18:03:00 armin76 Exp $

EAPI=2
inherit autotools eutils fdo-mime gnome2-utils qt4

DESCRIPTION="A Fast, Easy and Free BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com"
SRC_URI="http://download.${PN}bt.com/${PN}/files/${P}.tar.bz2"

LICENSE="MIT GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
IUSE="canberra cli daemon gtk libnotify qt4"

RDEPEND=">=dev-libs/libevent-1.4.11
	<dev-libs/libevent-2
	>=dev-libs/openssl-0.9.4
	|| ( >=net-misc/curl-7.16.3[openssl]
		>=net-misc/curl-7.16.3[ssl]
		>=net-misc/curl-7.16.3[gnutls] )
	gtk? ( >=dev-libs/glib-2.15.5:2
		>=x11-libs/gtk+-2.12:2
		>=dev-libs/dbus-glib-0.70
		>=gnome-base/gconf-2.26.0
		libnotify? ( >=x11-libs/libnotify-0.4.3 )
		canberra? ( >=media-libs/libcanberra-0.17 ) )
	qt4? ( x11-libs/qt-gui:4 )"
DEPEND="${RDEPEND}
	>=sys-devel/libtool-2.2
	sys-devel/gettext
	>=dev-util/intltool-0.40
	dev-util/pkgconfig
	sys-apps/sed"

pkg_setup() {
	if use cli; then
		ewarn "The cli version of transmission is considered depreated"
		ewarn "by the developers. Please use the daemon instead."
	fi
}

src_prepare() {
	sed -e 's:-g -O0::g' -e 's:-g -O3::g' -i configure.ac || die "sed failed"
	sed -e \
		's:$${TRANSMISSION_TOP}/third-party/libevent/.libs/libevent.a:-levent:' \
		-i qt/qtr.pro || die "sed failed"
	epatch "${FILESDIR}/${P}-disable-libevent.patch"
	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_enable gtk) \
		$(use_enable libnotify) \
		$(use_enable canberra libcanberra) \
		$(use_enable cli) \
		$(use_enable daemon)

	if use qt4; then
		cd qt
		eqmake4 qtr.pro
	fi
}

src_compile() {
	emake || die "emake failed"

	if use qt4; then
		cd qt
		emake || die "emake failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS NEWS
	rm -f "${D}"/usr/share/${PN}/web/LICENSE

	if use daemon; then
		newinitd "${FILESDIR}"/${PN}-daemon.initd.2 ${PN}-daemon
		newconfd "${FILESDIR}"/${PN}-daemon.confd.1 ${PN}-daemon
	fi

	if use qt4; then
		cd qt
		emake INSTALL_ROOT="${D}/usr" install || die "emake install failed"
		make_desktop_entry qtr "Transmission Qt BitTorrent Client" ${PN} \
			"Network;FileTransfer;P2P;Qt"
		use gtk || doicon qt/icons/transmission.png
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}