Updated ebuild

iulib-0.4-r1.ebuild (text/plain), 1.38 KB, created by Michał Górny on 2009-12-17 21:58:46 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit autotools multilib

DESCRIPTION="Easy-to-use image and video I/O functions"
HOMEPAGE="http://code.google.com/p/iulib/"
SRC_URI="http://iulib.googlecode.com/files/${P}.tgz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ffmpeg sdl v4l2"

RDEPEND="sys-libs/zlib
	media-libs/libpng
	media-libs/jpeg
	media-libs/tiff
	ffmpeg? ( media-video/ffmpeg )
	sdl? (
		media-libs/libsdl
		media-libs/sdl-gfx
	)"

src_prepare() {
	# fix missing -I CPPFLAGS
	epatch "${FILESDIR}"/${P}-cppflags-includes.diff
	# build shared library
	epatch "${FILESDIR}"/${P}-build-shared.diff
	# add --without-vidio & --without-v4l2 to control more depends
	epatch "${FILESDIR}"/${P}-automagic-depends.diff
	# fix modern ffmpeg support
	epatch "${FILESDIR}"/${P}-ffmpeg-pixelformat.diff
	# fix linking with ffmpeg
	epatch "${FILESDIR}"/${P}-ffmpeg-ldadd.diff

	python genAM.py > Makefile.am || die 'genAM.py failed.'
	eautoreconf
}

src_configure() {
	econf \
		$(use_with sdl SDL) \
		$(use_with ffmpeg vidio) \
		$(use_with v4l2)
}

src_install() {
	emake DESTDIR="${D}" install-am || die 'emake install failed.'
	dodoc CHANGES README TODO || die 'dodoc failed.'

	# .la file was needed only to compile shared lib, strip it now
	rm "${D}"/usr/$(get_libdir)/libiulib.la || die 'rm failed.'
}