# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/licq/licq-1.3.7.ebuild,v 1.1 2009/10/26 11:49:44 patrick Exp $

EAPI="1"

inherit eutils kde-functions multilib cmake-utils

MY_P=${P/_rc/-rc}
S="${WORKDIR}/${MY_P}"
CMAKE_USE_DIR="${S}/plugins/qt4-gui"

DESCRIPTION="ICQ Client with v8 support"
HOMEPAGE="http://www.licq.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
RESTRICT="mirror"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
IUSE="crypt debug kde kdeprefix msn ncurses nls qt3 qt4 socks5 ssl xosd"

# we use kde as KDE4
RDEPEND="kde? (
		qt4? ( >=kde-base/kdebase-meta-4.1 )
	)
	ssl? ( dev-libs/openssl )
	qt3? ( x11-libs/qt:3 )
	qt4? ( x11-libs/qt-gui:4 )
	nls? ( sys-devel/gettext )
	ncurses? ( sys-libs/ncurses dev-libs/cdk )
	crypt? ( app-crypt/gpgme:1 )
	xosd? ( x11-libs/xosd )"
DEPEND="${RDEPEND}
	dev-libs/boost"

#PATCHES=( "${FILESDIR}/${P}-glibc-2.10.patch" )

_generate_plugins_directories() {
	PLUGINS="auto-reply email rms"
	use msn && PLUGINS="${PLUGINS} msn"
	use ncurses && PLUGINS="${PLUGINS} console"
	use xosd && PLUGINS="${PLUGINS} osd"
	use qt3 && PLUGINS="${PLUGINS} qt-gui"
	# QT4 is something extra. Uses cmake.
	if use qt4; then
		PLUGINS_CMAKE="qt4-gui"
		if use kde; then
			if use kdeprefix; then
				ewarn "Sorry, no KDE4 support with kdeprefix enabled for now"
			else
				PLUGINS_CMAKE="kde4-gui"
				mycmakeargs="${mycmakeargs} -DWITH_KDE=ON"
			fi
		fi
	fi
	elog "I will generate these plugins/frontends for licq:"
	elog "${PLUGINS} ${PLUGINS_CMAKE}"
}

pkg_setup() {
	_generate_plugins_directories
}

src_compile() {
	local myconf myconf2 plugin
	# global config setup for automake
	myconf="$(use_enable ssl openssl)
		$(use_enable socks5)
		$(use_enable debug)
		$(use_enable nls)"

	einfo "Compiling Licq core."
	econf ${myconf} || die "econf failed"
	emake || die "emake failed"

	for plugin in ${PLUGINS}; do
		cd "${S}"/plugins/"${plugin}"
		einfo "Compiling Licq: \"${plugin}\"."
		if use qt3; then
			set-qtdir 3
			myconf2="${myconf2} --with-qt-libraries=${QTDIR}/$(get_libdir)"
		fi
		econf ${myconf} ${myconf2} || die "econf failed"
		emake || die "emake failed"
	done

	# we like qt4 it uses cmake
	if use qt4; then
		einfo "Compiling Licq: \"${PLUGINS_CMAKE}\"."
		cmake-utils_src_compile
	fi
}

src_install() {
	# install core
	einfo "Installing Licq core."
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc README* doc/*
	# Install the plug-ins
	for plugin in ${PLUGINS}; do
		cd "${S}"/plugins/"${plugin}"
		einfo "Installing Licq: \"${plugin}\"."
		emake DESTDIR="${D}" install || die "emake install failed"
		dodoc README* *.conf
	done
	if use qt4; then
		einfo "Installing Licq: \"${PLUGINS_CMAKE}\"."
		cmake-utils_src_install
		docinto plugins/qt4-gui
	fi

	exeinto /usr/share/${PN}/upgrade
	doexe "${S}"/upgrade/*

	# fixes bug #22136 and #149464
	rm -fR "${D}"/var
}