opendkim-1.1.1.ebuild

opendkim-1.1.1.ebuild (text/plain), 6.09 KB, created by steveb on 2009-10-20 23:29:42 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: Exp $

EAPI="2"

inherit eutils autotools toolchain-funcs

DESCRIPTION="Open source DKIM library and MTA filter implementation."
HOMEPAGE="http://opendkim.org"
SRC_URI="mirror://sourceforge/opendkim/${P}.tar.gz"

LICENSE="Sendmail-Open-Source"
SLOT="0"
KEYWORDS="~amd64 x86"
IUSE="+db diffheaders"

RDEPEND="dev-libs/openssl
	db? ( >=sys-libs/db-3.2 )
	diffheaders? ( >=dev-libs/tre-0.8.0 )"
DEPEND="${RDEPEND}
	|| ( mail-filter/libmilter mail-mta/sendmail )
	!mail-filter/dkim-milter"

QA_TEXTRELS="usr/lib/libopendkim.so.0.0.0"

pkg_setup() {
	enewgroup milter
	# mail-milter/spamass-milter creates milter user with this home directory
	# For consistency reasons, milter user must be created here with this home directory
	# even though this package doesn't need a home directory for this user (#280571)
	enewuser milter -1 -1 /var/lib/milter milter
}

src_prepare() {
	epatch "${FILESDIR}/${P}"-tre.patch
	eautoreconf
	sed -i -e 's:^\(# \(BaseDirectory\|KeyList\|LocalADSP\)[\t ]*\)\(/var/run/opendkim\|/var/db/dkim\|/etc/mail\)\(.*\):\1/etc/mail/opendkim\4:g' \
		-e 's:/var/db/[^/]*:/etc/mail/opendkim:g' \
		-e 's:^# \(UserID[\t ]*\).*:\1milter\:milter:g' \
		-e 's:^\(Socket[\t ]*\).*:\1local\:/var/run/opendkim/opendkim.sock:g' \
		opendkim/opendkim.conf.sample
	if use db; then
		( echo
		echo "##  Statistics filename"
		echo "##"
		echo "##  Names a file to which useful statistics will be saved."
		echo "##  See man opendkim-stats page"
		echo
		echo -ne "Statistics\t\t/var/run/opendkim/stats.db\n" ) >> \
			opendkim/opendkim.conf.sample
	fi
}

src_configure() {
	local myconf=""

	if use db; then
		myconf="${myconf} --enable-bodylengthdb"
		myconf="${myconf} --enable-popauth"
		myconf="${myconf} --enable-querycache"
		myconf="${myconf} --enable-stats"
	fi
	if use diffheaders; then
		myconf="${myconf} --enable-diffheaders"
		myconf="${myconf} --with-tre=/usr"
	fi
	if has_version mail-filter/dk-milter ; then
		myconf="${myconf} --with-domainkeys=/usr"
	else
		myconf="${myconf} --without-domainkeys"
	fi

	# myconf="${myconf} --with-unbound"

	myconf="${myconf} --enable-arlib"
	myconf="${myconf} --enable-dnsupgrade"
	myconf="${myconf} --enable-dkimreputation"
	myconf="${myconf} --enable-identityheader"
	myconf="${myconf} --enable-multiplesigs"
	myconf="${myconf} --enable-parsetime"
	myconf="${myconf} --enable-replacerules"
	myconf="${myconf} --enable-reportintervals "
	myconf="${myconf} --enable-selectcanon"
	myconf="${myconf} --enable-selectorheader"
	myconf="${myconf} --enable-sendermacro"
	myconf="${myconf} --enable-vbr"
	myconf="${myconf} --enable-ztags"
	myconf="${myconf} --with-milter=/usr"
	myconf="${myconf} --with-openssl=/usr"

	export CC="$(tc-getCC)" CXX="$(tc-getCXX)" LD="$(tc-getLD)"

	econf \
		--prefix="/usr" \
		--libdir="/usr/$(get_libdir)" \
		--mandir="/usr/share/man" \
		--sysconfdir="/etc/mail/${PN}" \
		${myconf} || die "configure failed"
}

src_compile() {
	emake -j1 CC="$(tc-getCC)" || die "emake failed"
}

src_test() {
	emake -j1 CC="$(tc-getCC)" OPTIONS=check || die "emake check failed"
}

src_install() {
	dodir /etc/mail/${PN} /var/run/${PN}
	fperms 770 /etc/mail/${PN}
	fowners milter:milter /etc/mail/${PN} /var/run/${PN}

	if use db; then
		dodir /var/lib/${PN}
		fperms 770 /var/lib/${PN}
		fowners milter:milter /var/lib/${PN}
	fi

	insinto /etc/mail/${PN}
	doins ${PN}/${PN}.conf.sample
	newins ${PN}/${PN}.conf.sample ${PN}.conf

	emake -j1 DESTDIR="${D}" LIBDIR="${D}/usr/$(get_libdir)" install \
		|| die "emake install failed"

	# file collision
	rm "${D}"/usr/share/man/man3/ar.3

	newinitd "${FILESDIR}/${PN}.init" ${PN} \
		|| die "newinitd failed"

	# some people like docs
	dodoc FEATURES KNOWNBUGS README RELEASE_NOTES RELEASE_NOTES.Sendmail docs/*.txt \
		|| die "failed to install docs"
}

pkg_postinst() {
	elog "If you want to sign your mail messages, you will have to run"
	elog "  emerge --config ${CATEGORY}/${PN}"
	elog "It will help you create your key and give you hints on how"
	elog "to configure your DNS and MTA."

	ewarn "Make sure your MTA has r/w access to the socket file."
	ewarn "This can be done either by setting UMask to 002 and adding MTA's user"
	ewarn "to milter group or you can simply set UMask to 000."
}

pkg_config() {
	local selector keysize pubkey

	read -p "Enter the selector name (default ${HOSTNAME}): " selector
	[ -n "${selector}" ] || selector=${HOSTNAME}
	if [ -z "${selector}" ]; then
		eerror "Oddly enough, you don't have a HOSTNAME."
		return 1
	fi
	if [ -f "${ROOT}"etc/mail/${PN}/${selector}.private ]; then
		ewarn "The private key for this selector already exists."
	else
		einfo "Select the size of private key:"
		einfo "  [1] 512 bits"
		einfo "  [2] 1024 bits"
		while read -n 1 -s -p "  Press 1 or 2 on the keyboard to select the key size " keysize ; do
			[ "${keysize}" == "1" || "${keysize}" == "2" ] && echo && break
		done
		case ${keysize} in
			1) keysize=512 ;;
			*) keysize=1024 ;;
		esac

		# generate the private and public keys
		${PN}-genkey -b ${keysize} -D "${ROOT}"etc/mail/${PN}/ \
			-s ${selector} && \
			chown milter:milter \
			"${ROOT}"etc/mail/${PN}/"${selector}".private || \
				{ eerror "Failed to create private and public keys." ; return 1; }
			chmod go-r "${ROOT}"etc/mail/${PN}/"${selector}".private
	fi

	# selector configuration
	echo
	einfo "Make sure you have the following settings in your dkim-filter.conf:"
	einfo "  Keyfile /etc/mail/${PN}/${selector}.private"
	einfo "  Selector ${selector}"

	# MTA configuration
	echo
	einfo "If you are using Postfix, add following lines to your main.cf:"
	einfo "  smtpd_milters     = unix:/var/run/${PN}/${PN}.sock"
	einfo "  non_smtpd_milters = unix:/var/run/${PN}/${PN}.sock"

	# DNS configuration
	einfo "After you configured your MTA, publish your key by adding this TXT record to your domain:"
	cat "${ROOT}"etc/mail/${PN}/${selector}.txt
	einfo "t=y signifies you only test the DKIM on your domain. See following page for the complete list of tags:"
	einfo "  http://www.dkim.org/specs/rfc4871-dkimbase.html#key-text"
	einfo
	einfo "Also look at the draft ADSP http://tools.ietf.org/html/rfc5617"
}