# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
inherit eutils cmake-utils

MY_P="OpenCV-${PV}"

DESCRIPTION="A collection of algorithms and sample code for various computer vision problems."
HOMEPAGE="http://opencv.willowgarage.com"
SRC_URI="mirror://sourceforge/${PN}library/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE="examples python ieee1394 ffmpeg gstreamer gtk jpeg2k jpeg mmx openmp png sse sse2 tiff v4l xine zlib -oldpython -octave -unicap"

COMMON_DEPEND="python? ( >=dev-lang/python-2.5 )
	ieee1394? ( >=sys-libs/libraw1394-1.2.0 media-libs/libdc1394:1 )
	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20080326 )
	gstreamer? ( media-libs/gstreamer )
	gtk? ( x11-libs/gtk+:2 )
	jpeg2k? ( media-libs/jasper )
	jpeg? ( media-libs/jpeg )
	png? ( media-libs/libpng:1.2 )
	tiff? ( media-libs/tiff )
	xine? ( media-libs/xine-lib )
	zlib? ( sys-libs/zlib )
	oldpython? ( >=dev-lang/python-2.5 >=dev-lang/swig-1.3.30 )
	octave? ( sci-mathematics/octave >=dev-lang/swig-1.3.30 )
	unicap? ( media-libs/unicap )"

DEPEND="${COMMON_DEPEND}
	>=dev-util/cmake-2.6
	dev-util/pkgconfig
	openmp? ( >=sys-devel/gcc-4.2[openmp] )"
RDEPEND="${COMMON_DEPEND}"

MAKEOPTS="${MAKEOPTS} -j1"

S="${WORKDIR}/${MY_P}"

src_configure() {
	mycmakeargs="${mycmakeargs} \
		$(cmake-utils_use_build python NEW_PYTHON_SUPPORT) \
		$(cmake-utils_use_build oldpython SWIG_PYTHON_SUPPORT) \
		$(cmake-utils_use_build octave OCTAVE_SUPPORT) \
		$(cmake-utils_use_build examples) \
		$(cmake-utils_use_enable openmp) \
		$(cmake-utils_use mmx USE_MMX) \
		$(cmake-utils_use sse USE_SSE) \
		$(cmake-utils_use sse2 USE_SSE2) \
		$(cmake-utils_use_with ieee1394 1394) \
		$(cmake-utils_use_with ffmpeg) \
		$(cmake-utils_use_with gstreamer) \
		$(cmake-utils_use_with gtk) \
		$(cmake-utils_use_with jpeg2k jasper) \
		$(cmake-utils_use_with jpeg) \
		$(cmake-utils_use_with png) \
		$(cmake-utils_use_with tiff) \
		$(cmake-utils_use_with unicap) \
		$(cmake-utils_use_with v4l) \
		$(cmake-utils_use_with xine)"
	cmake-utils_src_configure
}