pysolfc-1.1.ebuild

pysolfc-1.1.ebuild (text/plain), 2.15 KB, created by Mr. Bones. (RETIRED) on 2009-10-15 19:11:51 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit eutils python games

MY_PN=PySolFC
PNX="${MY_PN}-Cardsets"
PVX=1.1
DESCRIPTION="A collection of more than 1000 solitaire card games. It is a fork of PySol Solitaire."
HOMEPAGE="http://pysolfc.sourceforge.net/"
SRC_URI="mirror://sourceforge/pysolfc/${MY_PN}-${PV}.tar.bz2
	extra-cardsets? (
		mirror://sourceforge/pysolfc/${PNX}-${PVX}.tar.bz2
		mirror://debian/pool/main/p/${PNX}/${PNX}-${PVX}.tar.bz2
	)"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="+extra-cardsets"

DEPEND="dev-lang/python[tk]
	>=dev-lang/tk-8.4"

S=${WORKDIR}/PySolFC-${PV}

src_prepare() {
	rm -f Makefile # skip compilation
	mv data/pysol.xpm ./${PN}.xpm # save the useful icon
	rm -f data/{PySol.icns,pysol.ico,pysol.xbm} # and remove the rest
	find . -name "*.py[co]" -exec rm -f '{}' + # these will be recreated later
	mv data/html/ . # this should not be installed with data
	# put a valid search path for data on the settings
	sed -i \
		-e "s:/usr/share/PySolFC:${GAMES_DATADIR}/${MY_PN}/:g" \
		pysollib/settings.py \
		|| die "sed failed"

	if use extra-cardsets; then
		# remove the cardsets that come in the main tar
		# but only if they come on the extra tar as well
		local cardset
		for cardset in $(ls "${WORKDIR}"/${PNX}-${PVX}/); do
			rm -rf data/${cardset##*/}
		done
		# and put the extra cardsets in its place
		mv "${WORKDIR}"/${PNX}-${PVX}/* data/ || die
	fi
}

src_install() {
	insinto "$(games_get_libdir)"/${MY_PN}
	doins -r pysol.py pysollib || die "src failed"
	games_make_wrapper ${MY_PN} "python ./pysol.py" "$(games_get_libdir)"/${MY_PN}

	insinto "${GAMES_DATADIR}"/${MY_PN}
	doins -r data/* || die "data failed"

	doicon ${PN}.xpm
	make_desktop_entry PySolFC PySolFC /usr/share/pixmaps/${PN}.xpm

	doman docs/pysol.6
	dodoc README
	dohtml html/*
	domo po/ru.po

	#the html dir needs to appear in the data dir as well
	dosym "/usr/share/doc/${PF}"/html "${GAMES_DATADIR}"/${MY_PN}

	prepgamesdirs
}

pkg_postinst() {
	python_mod_optimize "$(games_get_libdir)"/${MY_PN}
	games_pkg_postinst
}

pkg_postrm() {
	python_mod_cleanup "$(games_get_libdir)"/${MY_PN}
}