# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$

EAPI="2"

MY_P="${P/-utils}"
DESCRIPTION="Set of utilities to simplify various dns(sec) tasks."
HOMEPAGE="http://www.nlnetlabs.nl/projects/ldns/"
SRC_URI="http://www.nlnetlabs.nl/downloads/ldns/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ssl"

DEPEND="~net-libs/ldns-${PV}[ssl?]
	net-libs/libpcap
	ssl? ( >=dev-libs/openssl-0.9.7 )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_configure() {
	cd "${S}"/drill
	econf \
		$(use_with ssl) \
		--disable-rpath || die

	cd "${S}"/examples
	econf \
		$(use_with ssl) \
		$(use_enable ssl sha2) \
		--disable-rpath || die
}

src_compile() {
	emake -C drill || die "emake for drill failed"
	emake -C examples || die "emake for examples failed"
}

src_install() {
	cd "${S}"/drill
	emake DESTDIR="${D}" install || die "emake install for drill failed"
	dodoc ChangeLog.22-nov-2005 README REGRESSIONS

	cd "${S}"/examples
	emake DESTDIR="${D}" install || die "emake install for examples failed"
	newdoc README README.examples
}