new ebuild

tora-2.1.0.ebuild (text/plain), 1.77 KB, created by Ondřej Súkup on 2009-09-09 22:01:19 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/tora/tora-2.0.0.ebuild,v 1.5 2009/06/26 18:41:53 dertobi123 Exp $

EAPI=2

inherit eutils multilib

DESCRIPTION="TOra - Toolkit For Oracle"
HOMEPAGE="http://tora.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="debug mysql oracle oci8-instant-client postgres debug"

DEPEND="x11-libs/qt-sql[mysql?,postgres?]
	>=x11-libs/qscintilla-2.1[qt4]
	oci8-instant-client? (
		dev-db/oracle-instantclient-basic
		dev-db/oracle-instantclient-sqlplus )"
RDEPEND="${DEPEND}"

pkg_setup() {
	if ( use oracle || use oci8-instant-client ) && [ -z "$ORACLE_HOME" ] ; then
		eerror "ORACLE_HOME variable is not set."
		eerror
		eerror "You must install Oracle >= 8i client for Linux in"
		eerror "order to compile TOra with Oracle support."
		eerror
		eerror "Otherwise specify -oracle in your USE variable."
		eerror
		eerror "You can download the Oracle software from"
		eerror "http://otn.oracle.com/software/content.html"
		die
	fi
}

src_configure() {
	local myconf
	myconf="--with-qt-libraries=/usr/$(get_libdir)/qt4"
	use debug && myconf="$myconf --enable-debug"
	use oracle && myconf="$myconf --with-oracle=${ORACLE_HOME}"
	use oci8-instant-client && myconf="$myconf --with-instant-client=${ORACLE_HOME}"
	if use oci8-instant-client || use oracle ; then
		myconf="$myconf --with-oracle-libraries=${ORACLE_HOME}/lib \
		--with-oracle-includes=${ORACLE_HOME}/include "
	fi
	econf $myconf
}

src_compile() {
	emake -j1 || die "make die"
}

src_install() {
	emake install DESTDIR="${D}" || die
	domenu "${FILESDIR}"/${PN}.desktop || die
	doicon "${FILESDIR}"/${PN}.png || die
}