# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:  $

inherit autotools distutils eutils flag-o-matic toolchain-funcs versionator python multilib

DESCRIPTION="SALOME : The Open Source Integration Platform for Numerical
Simulation. YACS component"
HOMEPAGE="http://www.salome-platform.org"
MODULE_NAME="YACS"
SRC_URI="${MODULE_NAME}sourcesV${PV}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="debug doc mpi opengl"

RDEPEND="opengl?  ( virtual/opengl )
	 mpi?     ( sys-cluster/mpich2 )
	 debug?   ( dev-util/cppunit )
	 >=sci-misc/salome-kernel-${PV}
	 >=sci-misc/salome-gui-${PV}
	>=dev-python/omniorbpy-3.3
	>=sci-libs/hdf5-1.6.4
	dev-libs/boost
	>=x11-libs/qt-core-4.4.3
	>=x11-libs/qt-gui-4.4.3
	>=x11-libs/qt-opengl-4.4.3
	>=x11-libs/qwt-5.1.1
	>=x11-libs/qscintilla-2.3
	>=dev-python/PyQt4-4.4.3
	>=dev-python/sip-4.7.7
	=sci-libs/vtk-5.0*[python]
	>=sci-libs/opencascade-6.3-r6
	>=net-misc/omniORB-4.1.3
	 "

DEPEND="${RDEPEND}
	>=app-doc/doxygen-1.5.6
	media-gfx/graphviz
	>=dev-python/docutils-0.4
	>=dev-python/sip-4.7.7
	dev-lang/swig
	dev-libs/libxml2
	>=dev-python/celementtree-1.0.5
	>=dev-python/elementtree-1.2.6
	"

MY_S="${WORKDIR}/${MODULE_NAME}_SRC_${PV}"
INSTALL_DIR="/opt/salome-${PV}/${MODULE_NAME}"


src_unpack() {
	python_version
	distutils_python_version

	unpack ${A}

	cd "${MY_S}"
	epatch "${FILESDIR}"/${P}-lib_location.patch
	epatch "${FILESDIR}"/${P}-python-libdir.patch

	rm -r -f autom4te.cache
	./build_configure
}


src_compile() {
	local myconf=""
	cd "${MY_S}"

	# Specifying --without-<flag> for mpich
	# has the same effect as turning it on
	# so we just ommit it if it's not required to turn it off
	if use mpi ; then
		myconf="${myconf} --with-mpich"
	fi

	# Configuration
	econf --prefix=${INSTALL_DIR} \
	      --datadir=${INSTALL_DIR}/share/salome \
	      --docdir=${INSTALL_DIR}/doc/salome \
	      --infodir=${INSTALL_DIR}/share/info \
		  --with-qt4="/usr" \
		  --with-qt4-libraries="/usr/lib/qt4" \
	      ${myconf} \
	      $(use_enable debug ) \
	      $(use_enable !debug production ) \
	      $(use_with debug cppunit /usr ) \
	|| die "configuration failed"

	# Compilation
	MAKEOPTS="-j1" emake || die "Compilation failed"
}


src_install() {
	cd "${MY_S}"

	emake DESTDIR="${D}" install || die "Installation failed"

	if use amd64 ; then
		dosym ${INSTALL_DIR}/lib64 ${INSTALL_DIR}/lib
	fi

	echo "${MODULE_NAME}_ROOT_DIR=${INSTALL_DIR}" > ./90${P}
	echo "LDPATH=${INSTALL_DIR}/$(get_libdir)/salome" >> ./90${P}
	echo "PATH=${INSTALL_DIR}/bin/salome" >> ./90${P}
	echo "PYTHONPATH=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome" >> ./90${P}
	doenvd 90${P}
	rm adm_local/Makefile adm_local/unix/make_commence adm_local/unix/make_conclude adm_local/unix/make_omniorb
	insinto "${INSTALL_DIR}"
	doins -r adm_local
	if use doc ; then
		dodoc AUTHORS INSTALL NEWS README README.FIRST.txt
	fi

}

pkg_postinst() {
	elog "Run \`env-update && source /etc/profile\`"
	elog "now to set up the correct paths."
	elog ""
}