# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:  $

inherit autotools distutils eutils flag-o-matic toolchain-funcs versionator python multilib

DESCRIPTION="SALOME : The Open Source Integration Platform for Numerical Simulation. SMESH Component"
HOMEPAGE="http://www.salome-platform.org"
MODULE_NAME="SMESH"
SRC_URI="${MODULE_NAME}sourcesV${PV}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="debug doc mpi opengl"

RDEPEND="opengl?  ( virtual/opengl )
	mpi?     ( sys-cluster/mpich2 )
	debug?   ( dev-util/cppunit )
	>=sci-misc/salome-kernel-${PV}
	>=sci-misc/salome-med-${PV}
	>=sci-misc/salome-geom-${PV}
	>=dev-python/omniorbpy-3.3
	>=net-misc/omniORB-4.1.3
	>=x11-libs/qt-core-4.4.3
	>=x11-libs/qt-gui-4.4.3
	>=x11-libs/qt-opengl-4.4.3
	dev-libs/boost
	>=sci-libs/opencascade-6.3-r6
	>=sci-libs/hdf5-1.6.4
	>=sci-libs/med-2.3.5
	=sci-libs/vtk-5.0*[python]
	"

DEPEND="${RDEPEND}
	dev-lang/swig
	>=app-doc/doxygen-1.5.6
	media-gfx/graphviz
	>=dev-python/docutils-0.4
	"

MY_S="${WORKDIR}/${MODULE_NAME}_SRC_${PV}"
INSTALL_DIR="/opt/salome-${PV}/${MODULE_NAME}"
SMESH_ROOT_DIR="/opt/salome-${PV}/${MODULE_NAME}"
export OPENPBS="/usr"

src_unpack() {
	python_version
	distutils_python_version

	unpack ${A}
	cd "${MY_S}"

}


src_compile() {
	local myconf=""
	cd "${MY_S}"
	rm -r -f autom4te.cache
	./build_configure

	# Specifying --without-<flag> for mpi / mpich
	# has the same effect as turning it on
	# so we just ommit it if it's not required to turn it off
	if use mpi ; then
		myconf="${myconf} --with-mpi --with-mpich"
	fi

	# Configuration
	econf --prefix=${INSTALL_DIR} \
	      --datadir=${INSTALL_DIR}/share/salome \
	      --docdir=${INSTALL_DIR}/doc/salome \
	      --infodir=${INSTALL_DIR}/share/info \
	      --with-python-site=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome \
	      --with-python-site-exec=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome \
		  --with-qt="/usr" \
		  --with-qwt_inc="/usr/include/qwt5" \
	      ${myconf} \
	      $(use_enable debug ) \
	      $(use_enable !debug production ) \
	      $(use_with debug cppunit /usr ) \
	      $(use_with opengl opengl /usr) \
	|| die "configuration failed"

	# Compilation
	MAKEOPTS="-j1" emake || die "Compilation failed"
}


src_install() {
	cd "${MY_S}"

	# Installation
	emake prefix="${D}/${INSTALL_DIR}" \
	      docdir="${D}/${INSTALL_DIR}/doc/salome" \
	      infodir="${D}/${INSTALL_DIR}/share/info" \
	      datadir="${D}/${INSTALL_DIR}/share/salome" \
	      pythondir="${D}/${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages" install \
	|| die "emake install failed"

	if use amd64 ; then
		dosym ${INSTALL_DIR}/lib64 ${INSTALL_DIR}/lib
	fi

	echo "${MODULE_NAME}_ROOT_DIR=${INSTALL_DIR}" > ./90${P}
	echo "LDPATH=${INSTALL_DIR}/$(get_libdir)/salome" >> ./90${P}
	echo "PATH=${INSTALL_DIR}/bin/salome" >> ./90${P}
	echo "PYTHONPATH=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome" >> ./90${P}
	doenvd 90${P}
	rm adm_local/Makefile adm_local/unix/make_commence adm_local/unix/make_conclude adm_local/unix/make_omniorb
	insinto "${INSTALL_DIR}"
	doins -r adm_local
	if use doc ; then
		dodoc INSTALL
	fi
}


pkg_postinst() {
	elog "Run \`env-update && source /etc/profile\`"
	elog "now to set up the correct paths."
	elog ""
}