# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:  $

inherit autotools distutils eutils flag-o-matic toolchain-funcs versionator python multilib

DESCRIPTION="SALOME : The Open Source Integration Platform for Numerical Simulation. MED Component"
HOMEPAGE="http://www.salome-platform.org"
MODULE_NAME="MED"
SRC_URI="${MODULE_NAME}sourcesV${PV}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="debug doc mpi opengl openpbs metis scotch"

RDEPEND="opengl?  ( virtual/opengl )
	mpi?     ( sys-cluster/mpich2 )
	debug?   ( dev-util/cppunit )
	openpbs? ( sys-cluster/torque )
	metis?	( >=sci-libs/metis-4.0  )
	scotch?	( >=sci-libs/scotch-4.0 )
	>=sci-misc/salome-kernel-${PV}
	>=sci-misc/salome-gui-${PV}
	>=x11-libs/qt-core-4.4.3
	>=x11-libs/qt-gui-4.4.3
	>=x11-libs/qt-opengl-4.4.3
	dev-libs/boost
	>=sci-libs/opencascade-6.3-r6
	>=sci-libs/med-2.3.5"

DEPEND="${RDEPEND}
	dev-lang/swig
	dev-libs/libxml2
	"

MY_S="${WORKDIR}/${MODULE_NAME}_SRC_${PV}"
INSTALL_DIR="/opt/salome-${PV}/${MODULE_NAME}"
MED_ROOT_DIR="/opt/salome-${PV}/${MODULE_NAME}"
export OPENPBS="/usr"

src_unpack() {
	python_version
	distutils_python_version

	unpack ${A}
	cd "${MY_S}"
	epatch "${FILESDIR}"/${P}-qt4-path.patch
	epatch "${FILESDIR}"/${P}-med_int.patch
	epatch "${FILESDIR}"/${P}-med_int_2.patch

}


src_compile() {
	local myconf=""
	cd "${MY_S}"
	rm -r -f autom4te.cache
	./clean_configure
	./build_configure
	# CXXFLAGS are slightly modified to allow the compilation of
	# salome-med with OpenCascade and gcc-4.1.x
	if version_is_at_least "4.1" $(gcc-version) ; then
		append-flags -ffriend-injection -fpermissive
	fi

	# Specifying --without-<flag> for mpi / mpich / openpbs
	# has the same effect as turning it on
	# so we just ommit it if it's not required to turn it off
	if use mpi ; then
		myconf="${myconf} --with-mpi --with-mpich"
	fi
	if use openpbs ; then
		myconf="${myconf} --with-openpbs"
	fi
	if use debug ; then
		myconf="${myconf} --with-cppunit_inc=/usr/include/cppunit"
	else
		myconf="${myconf} --disable-cppunit"
	fi
	

	# Configuration
	econf --prefix=${INSTALL_DIR} \
	      --datadir=${INSTALL_DIR}/share/salome \
	      --docdir=${INSTALL_DIR}/doc/salome \
	      --infodir=${INSTALL_DIR}/share/info \
	      --with-python-site=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome \
	      --with-python-site-exec=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome \
		  --without-scotch \
		  --without-metis \
		  --with-qt="/usr" \
	      ${myconf} \
	      $(use_enable debug ) \
	      $(use_enable !debug production ) \
	      $(use_with opengl opengl /usr) \
	|| die "configuration failed"

	# Compilation
	MAKEOPTS="-j1" emake || die "Compilation failed"
}


src_install() {
	cd "${MY_S}"

	emake prefix="${D}/${INSTALL_DIR}" \
	      docdir="${D}/${INSTALL_DIR}/doc/salome" \
	      infodir="${D}/${INSTALL_DIR}/share/info" \
	      datadir="${D}/${INSTALL_DIR}/share/salome" \
	      pythondir="${D}/${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages" install \
	|| die "emake install failed"

	if use amd64 ; then
		dosym ${INSTALL_DIR}/lib64 ${INSTALL_DIR}/lib
	fi

	echo "${MODULE_NAME}_ROOT_DIR=${INSTALL_DIR}" > ./90${P}
	echo "LDPATH=${INSTALL_DIR}/$(get_libdir)/salome" >> ./90${P}
	echo "PATH=${INSTALL_DIR}/bin/salome" >> ./90${P}
	echo "PYTHONPATH=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome" >> ./90${P}
	doenvd 90${P}
	rm adm_local/Makefile adm_local/unix/make_commence adm_local/unix/make_conclude adm_local/unix/make_omniorb
	insinto "${INSTALL_DIR}"
	doins -r adm_local
	if use doc; then
		dodoc INSTALL README
	fi
}

pkg_postinst() {
	elog "Run \`env-update && source /etc/profile\`"
	elog "now to set up the correct paths."
	elog ""
}