# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:  $

inherit autotools distutils eutils flag-o-matic toolchain-funcs versionator python multilib

DESCRIPTION="SALOME : The Open Source Integration Platform for Numerical Simulation. GEOM component"
HOMEPAGE="http://www.salome-platform.org"
MODULE_NAME="GEOM"
SRC_URI="${MODULE_NAME}sourcesV${PV}.tar.gz"

# NOTES
# The Sourcecode for the Salome 5.1.2 has to be extracted from
# the Salome 5.1.2 Installer
# Instructions:
# Download an InstallWizard*.tar.gz from http://www.salome-platform.org/download/dl512/
# (you have to register to download)
# Theoretically it would be possible to use
# http://files.opencascade.com/Salome/Salome5.1.2/src5.1.2.tar.gz
# but you'd have to download the Installer anyway because of the new version of
# opencascade required
# unpack the InstallWizard*tar.gz and you'll find the sources in
# -/InstallWizard*/Products/SOURCES
# copy GEOMsourcesV5.1.2 to DISTDIR



LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="debug doc mpi opengl"

RDEPEND="opengl?  ( virtual/opengl )
	 mpi?     ( sys-cluster/mpich2 )
	 debug?   ( dev-util/cppunit )
	>=sci-misc/salome-kernel-${PV}
	>=sci-misc/salome-gui-${PV}
	>=dev-python/omniorbpy-3.3
	>=net-misc/omniORB-4.1.3
	>=x11-libs/qt-core-4.4.3
	>=x11-libs/qt-gui-4.4.3
	>=x11-libs/qt-opengl-4.4.3
	>=sci-libs/opencascade-6.3-r6
	dev-libs/boost
	>=sci-libs/hdf5-1.6.4
	=sci-libs/vtk-5.0*[python]
	"

DEPEND="${RDEPEND}
	>=app-doc/doxygen-1.5.6
	media-gfx/graphviz
	>=dev-python/docutils-0.4
	dev-lang/swig
	"

MY_S="${WORKDIR}/${MODULE_NAME}_SRC_${PV}"
INSTALL_DIR="/opt/salome-${PV}/${MODULE_NAME}"
GEOM_ROOT_DIR="/opt/salome-${PV}/${MODULE_NAME}"
export OPENPBS="/usr"

src_unpack() {
	python_version
	distutils_python_version


	unpack ${A}
	cd "${MY_S}"
	epatch "${FILESDIR}"/${P}-qt4-path.patch

}


src_compile() {
	local myconf=""
	cd "${MY_S}"
	rm -r -f autom4te.cache
	./clean_configure
	./build_configure

	# Specifying --without-<flag> for mpich
	# has the same effect as turning it on
	# so we just ommit it if it's not required to turn it off
	if use mpi ; then
		myconf="${myconf} --with-mpich"
	fi

	# Configuration
	econf --prefix=${INSTALL_DIR} \
	      --datadir=${INSTALL_DIR}/share/salome \
	      --docdir=${INSTALL_DIR}/doc/salome \
	      --infodir=${INSTALL_DIR}/share/info \
	      --libdir=${INSTALL_DIR}/$(get_libdir)/salome \
	      --with-python-site=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome \
	      --with-python-site-exec=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome \
		  --with-qt="/usr" \
	      ${myconf} \
	      $(use_enable debug ) \
	      $(use_enable !debug production ) \
	      $(use_with debug cppunit /usr ) \
	      $(use_with opengl opengl /usr) \
	|| die "configuration failed"

	# Compilation
	MAKEOPTS="-j1" emake || die "Compilation failed"
}


src_install() {
	cd "${MY_S}"

	# Installation
	emake prefix="${D}/${INSTALL_DIR}" \
	      docdir="${D}/${INSTALL_DIR}/doc/salome" \
	      infodir="${D}/${INSTALL_DIR}/share/info" \
	      datadir="${D}/${INSTALL_DIR}/share/salome" \
	      pythondir="${D}/${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages" install \
	|| die "emake install failed"

	if use amd64 ; then
		dosym ${INSTALL_DIR}/lib64 ${INSTALL_DIR}/lib
	fi

	echo "${MODULE_NAME}_ROOT_DIR=${INSTALL_DIR}" > ./90${P}
	echo "LDPATH=${INSTALL_DIR}/$(get_libdir)/salome" >> ./90${P}
	echo "PATH=${INSTALL_DIR}/bin/salome" >> ./90${P}
	echo "PYTHONPATH=${INSTALL_DIR}/$(get_libdir)/python${PYVER}/site-packages/salome" >> ./90${P}
	doenvd 90${P}
	rm adm_local/Makefile adm_local/unix/make_commence adm_local/unix/make_conclude adm_local/unix/make_omniorb
	insinto "${INSTALL_DIR}"
	doins -r adm_local
	if use doc ; then
		dodoc INSTALL
	fi
}


pkg_postinst() {
	elog "Run \`env-update && source /etc/profile\`"
	elog "now to set up the correct paths."
	elog ""
}