ebuild with linguas, cli and daemon use flags

transmission-1.72.ebuild (text/plain), 2.19 KB, created by Nikoli on 2009-07-01 10:11:04 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit autotools fdo-mime gnome2-utils qt4

DESCRIPTION="A Fast, Easy and Free BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com"
SRC_URI="http://download.${PN}bt.com/${PN}/files/${P}.tar.bz2"

LICENSE="MIT GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="cli daemon gtk libnotify qt4"

LANGS="ar bg br bs ca cs da de el en_GB eo es et eu fa fi fil fr ga gl he hu id is it ja ka kk ko ku li lt lv mk ml ms mt nb nl nn pl pt pt_BR ro ru sk sl sq sr sv te th tr uk vi zh_CN zh_TW"

for L in $LANGS; do
	IUSE="$IUSE linguas_$L"
done

RDEPEND=">=dev-libs/libevent-1.4.11
	<dev-libs/libevent-2
	>=dev-libs/openssl-0.9.4
	|| ( >=net-misc/curl-7.16.3[ssl]
		>=net-misc/curl-7.16.3[gnutls] )
	gtk? ( >=dev-libs/glib-2.15.5:2
		>=x11-libs/gtk+-2.6:2
		>=dev-libs/dbus-glib-0.70
		libnotify? ( >=x11-libs/libnotify-0.4.3 ) )
	qt4? ( x11-libs/qt-gui:4 )"
DEPEND="${RDEPEND}
	>=sys-devel/libtool-2.2
	sys-devel/gettext
	dev-util/intltool
	dev-util/pkgconfig
	sys-apps/sed"

src_prepare() {
	sed -e 's:-g -O0::g' -e 's:-g -O3::g' -i configure.ac || die "sed failed"
	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_enable cli) \
		$(use_enable daemon) \
		$(use_enable gtk) \
		$(use_enable libnotify)

	if use qt4; then
		cd qt
		eqmake4 qtr.pro
	fi
}

src_compile() {
	emake || die "emake failed"

	if use qt4; then
		cd qt
		emake || die "emake failed"
	fi
}

src_install() {
	# process linguas
	local langs=
	for lingua in $LINGUAS; do
		if has $lingua $LANGS; then
			langs="$langs ${lingua}"
		fi
	done

	emake DESTDIR="${D}" USE_LINGUAS="${langs}" install || die "emake install failed"

	dodoc AUTHORS NEWS
	rm -f "${D}"/usr/share/${PN}/web/LICENSE

	newinitd "${FILESDIR}"/${PN}-daemon.initd.2 ${PN}-daemon
	newconfd "${FILESDIR}"/${PN}-daemon.confd.1 ${PN}-daemon

	if use qt4; then
		cd qt
		emake INSTALL_ROOT="${D}/usr" install || die "emake install failed"
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}