# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic subversion games

DESCRIPTION="3D real-time strategy game"
HOMEPAGE="http://wz2100.net/"

ESVN_REPO_URI="https://warzone2100.svn.sourceforge.net/svnroot/warzone2100/trunk"
ESVN_BOOTSTRAP="autogen.sh"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
# upstream requested debug support
IUSE="debug nls"

RDEPEND=">=dev-games/physfs-1.0.1
	dev-libs/popt
	>=media-libs/libsdl-1.2[opengl]
	>=media-libs/libpng-1.2
	>=media-libs/libvorbis-1.1
	>=media-libs/openal-0.0.8-r1
	>=media-libs/quesoglc-0.6.5
	>=media-libs/sdl-net-1.2
	virtual/glu
	nls? ( virtual/libintl )
	virtual/opengl"
DEPEND="${RDEPEND}
	app-arch/zip
	>=dev-util/pkgconfig-0.9
	nls? ( >=sys-devel/gettext-0.15 )"

pkg_setup() {
	# built_with_use media-libs/libsdl opengl || die "Please enable the 'opengl' useflag for media-libs/libsdl."
	games_pkg_setup
}

src_unpack() {
	subversion_src_unpack
}

src_compile() {
	local confopts="--disable-dependency-tracking \
		--docdir=/usr/share/doc/${PF} \
		--with-icondir=/usr/share/pixmaps \
		--with-applicationdir=/usr/share/applications \
		$(use_enable nls)"

	# Enabling debug-mode means nothing more than enabling cheat-codes without
	# taking care of your CFLAGS!
	confopts="${confopts} \
		$(use_enable debug)"

	# You might want to enable this line in case you want to actively hunt bugs
	# for the WZ2100-project and you have this file stored in your local
	# overlay.
	#use debug && strip-flags && append-flags "-g3 -O0"

	egamesconf ${confopts} || die "egamesconf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	prepgamesdirs
}