Ebuild for the live CVS version

pdfedit-9999.ebuild (text/plain), 1.36 KB, created by Alexey Charkov on 2009-06-14 13:43:24 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools qt3 cvs

DESCRIPTION="Editor for manipulating PDF documents. GUI and commandline interface."
HOMEPAGE="http://pdfedit.petricek.net/"
SRC_URI=""
ECVS_SERVER="pdfedit.cvs.sourceforge.net:/cvsroot/pdfedit"
ECVS_MODULE="pdfedit"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"

IUSE="doc"
RDEPEND="=x11-libs/qt-3*
	media-libs/t1lib"
DEPEND="${RDEPEND}
	dev-libs/boost
	doc? ( app-doc/doxygen )"

S=${WORKDIR}/${PN}

src_unpack() {
	cvs_src_unpack
	cd "${S}"

	# Prevent overwriting the users' C{,XX}FLAGS
	sed -i 's/CFLAGS = $(CONFIG_CFLAGS)//' Makefile.flags.in
	sed -i 's/CXXFLAGS = $(CONFIG_CXXFLAGS)//' Makefile.flags.in
	sed -i 's/QMAKE_CXXFLAGS += $(CONFIG_CXXFLAGS)//' src/kpdf-kde-3.3.2/qoutputdevices.pro
	sed -i 's/QMAKE_CFLAGS += $(CONFIG_CFLAGS)//' src/gui/pdfedit.pro
	sed -i 's/QMAKE_CXXFLAGS += $(CONFIG_CXXFLAGS) $(EXTRA_GUI_CXXFLAGS)/QMAKE_CXXFLAGS += $(EXTRA_GUI_CXXFLAGS)/' src/gui/pdfedit.pro

	# Prevent overwriting the users' MAKEOPTS
	sed -i 's/MAKEFLAGS += @parallel_make@/MAKEFLAGS += $(MAKEOPTS)/' Makefile.rules.in

	eautoreconf
}

src_compile() {
	econf $(use_enable doc doxygen-doc) $(use_enable doc advanced-doc)
	emake || die "emake failed"
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"
}