# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
GCONF_DEBUG=no
inherit gnome2 multilib

DESCRIPTION="A browser plug-in for GNOME MPlayer."
HOMEPAGE="http://code.google.com/p/gecko-mediaplayer"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gnome"

RDEPEND="
	dev-libs/glib:2
	=media-video/gnome-mplayer-${PV}
	net-libs/xulrunner:1.9
	dev-libs/nspr
	>=sys-apps/dbus-0.95
	>=dev-libs/dbus-glib-0.70
	gnome? ( gnome-base/gconf:2 )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

G2CONF="$(use !gnome && echo "--disable-schemas-install")"

DOCS="ChangeLog INSTALL
	DOCS/tech/javascript.txt"
src_install() {
	gnome2_src_install
	dodir /usr/$(get_libdir)/nsbrowser/plugins
	mv "${D}"/usr/$(get_libdir)/nspr/mozilla/plugins/${PN}* \
		"${D}"/usr/$(get_libdir)/nsbrowser/plugins || die "mv plugins failed."
	rm -rf "${D}"/usr/$(get_libdir)/nspr
	rm -rf "${D}"/usr/share/doc/${PN}
	rm -rf "${D}"/var
}