dev-java/jogl-1.1.2_pre20080523.ebuild

jogl-1.1.2_pre20080523.ebuild (text/plain), 1.40 KB, created by Florian Manschwetus on 2009-03-10 11:27:55 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit java-pkg-2

DESCRIPTION="Java Bindings for OpenGL from the Java Gaming Initiative."

HOMEPAGE="https://jogl.dev.java.net/"

SRC_URI="http://download.java.net/media/jogl/builds/nightly/${P/_pre/-pre-}-src.zip"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="doc"
S="${WORKDIR}/jogl"

DEPEND=">=dev-java/ant-1.7.1
	>=dev-java/antlr-2.7.7
	>=virtual/jdk-1.6
	virtual/opengl"

RDEPEND=">=virtual/jdk-1.6
	virtual/opengl"

src_compile() {
	# Clear the classpath
	CLASSPATH="."

	# This property is needed for JOGL's build.xml
	ANTLR="-Dantlr.jar=/usr/share/antlr/lib/antlr.jar"

	# build.xml is located inside the make directory
	cd make

	ant ${ANTLR} all || {
        	eerror "Compiling jogl failed. Please make sure that ant was built with antlr support!"
		eerror " Make sure that antlr is emerged, then re-emerge ant."
		die
	}

	# Build documentation if the doc use flag is set
	if use doc; then
		einfo "Building documentation"
		ant ${ANTLR} javadoc || {
			eerror "Failed to build documentation."
			die
		}
	fi
}

src_install() {
	# Install the jogl main library as a Java package
	java-pkg_dojar build/jogl.jar

	# Install the native library
	dolib.so build/obj/libjogl.so

	# Install the documentation if the doc USE flag is set
	if use doc; then
		dohtml -r javadoc_public/*
	fi
}