# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils games qt4

MY_P="PokerTH-${PV}-2-src"

DESCRIPTION="Texas Hold'em poker game"
HOMEPAGE="http://www.pokerth.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
RESTRICT="mirror"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated"

DEPEND=">=dev-libs/boost-1.34.1
	>=net-libs/gnutls-2.2.2
	>=net-misc/curl-7.16
	media-libs/libsdl
	media-libs/sdl-mixer[mikmod]
	sys-libs/zlib
	x11-libs/qt-gui:4"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_configure() {
	if ! use dedicated ; then
		sed -i -e '/SUBDIRS/s/pokerth_server\.pro//' pokerth.pro || die
	fi
	eqmake4
}

src_install() {
	dogamesbin ${PN} || die

	insinto "${GAMES_DATADIR}/${PN}"
	doins -r data || die
	dodoc ChangeLog TODO docs/{net_protocol,server_setup_howto}.txt || die

	domenu ${PN}.desktop
	doicon ${PN}.png

	if use dedicated ; then
		dogamesbin bin/pokerth_server || die
	fi

	prepgamesdirs
}