# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit cmake-utils 

DESCRIPTION="Winamp-like audio player written with Qt4"
HOMEPAGE="http://qmmp.ylsoftware.com/"
SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"

RESTRICT="mirror" # for now...

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="alsa dbus ffmpeg flac jack libsamplerate mad modplug musepack oss pulseaudio scrobbler sndfile vorbis wavpack"

RDEPEND="|| ( (
				x11-libs/qt-core
				x11-libs/qt-gui )
				=x11-libs/qt-4.3.0:4 )
	>=media-libs/taglib-1.4
	alsa? ( >=media-libs/alsa-lib-1.0.1 )
	dbus? ( >=sys-apps/dbus-1.0.2 )
	flac? ( >=media-libs/flac-1.1.3 )
	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
	mad? ( >=media-libs/libmad-0.15.1b )
	musepack? ( >=media-libs/libmpcdec-1.2.5 )
	modplug? ( >=media-libs/libmodplug-0.8.4 )
	vorbis? ( >=media-libs/libvorbis-1.1.2
				media-libs/libogg )
	jack? ( >=media-sound/jack-audio-connection-kit-0.102.5 
			>=media-libs/libsamplerate-0.1.2 )
	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20070330 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
	wavpack? ( >=media-sound/wavpack-4.41 )
	scrobbler? ( >=net-misc/curl-7.16 )
	sndfile? ( >=media-libs/libsndfile-1.0.17 )"
DEPEND="${RDEPEND}
	>=dev-util/cmake-2.4.8"

DOCS="AUTHORS ChangeLog README"
	
qmmp_use_enable() {
	# Uses completely non standard cmake options, so damn ugly ones even...
	use ${2} && echo "-DUSE_${1}:BOOL=TRUE" || echo "-DUSE_${1}:BOOL=FALSE"
}

src_compile() {
	# needs to be built in source tree
	CMAKE_IN_SOURCE_BUILD=1

	mycmakeargs="${mycmakeargs}
		$(qmmp_use_enable ALSA alsa)
		$(qmmp_use_enable DBUS dbus)
		$(qmmp_use_enable FFMPEG ffmpeg)
		$(qmmp_use_enable FLAC flac)
		$(qmmp_use_enable JACK jack)
		$(qmmp_use_enable MAD mad)
		$(qmmp_use_enable MODPLUG modplug)
		$(qmmp_use_enable MPC musepack)
		$(qmmp_use_enable OSS oss)
		$(qmmp_use_enable PULSE pulseaudio)
		$(qmmp_use_enable SCROBBLER scrobbler)
		$(qmmp_use_enable SNDFILE sndfile)
		$(qmmp_use_enable SRC libsamplerate)
		$(qmmp_use_enable VORBIS vorbis)
		$(qmmp_use_enable WAVPACK wavpack)
		"
	#fails with -j > 1 here
	cmake-utils_src_compile
}