Ebuild for jabref emacs integration

jabref-pushtoemacsclient-1.0.ebuild (text/plain), 1.17 KB, created by peyser.alex on 2008-11-08 00:12:23 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=1
JAVA_PKG_IUSE=""

inherit eutils java-pkg-2 java-ant-2

MY_PN="PushToEmacsclient"

DESCRIPTION="JabRef plugin for inserting citations into Emacs"
HOMEPAGE="http://jabref.sourceforge.net/revisionhistory.php"
SRC_URI="http://jabref.sourceforge.net/plugins/${MY_PN}.zip"

LICENSE="GPL"
SLOT="0"
KEYWORDS="~x86 ~sparc ~ppc ~amd64 ~ppc64"
IUSE=""

COMMON_DEP="
		>=app-text/jabref-2.4.2
		>=dev-java/jgoodies-forms-1.1.0
		>=dev-java/glazedlists-1.7.0"

RDEPEND=">=virtual/jre-1.5
		${COMMON_DEP}"

DEPEND=">=virtual/jdk-1.5
		${COMMON_DEP}"

S=${WORKDIR}/pushto_emacsclient

RESTRICT="mirror"

src_unpack() {
		unpack ${A}
		cd "${S}"
		einfo "Patching build.xml"
		sed -ire \
			's/name="JabRef-.*\.jar"/name="*.jar"/' \
			build.xml || die

		cd lib
		rm -v *.jar || die
		java-pkg_jar-from jabref
		java-pkg_jar-from jgoodies-forms
		java-pkg_jar-from glazedlists
}

src_install() {
		java-pkg_jarinto /usr/share/jabref/lib/plugins/
		java-pkg_newjar \
			lib/plugins/net.sf.jabref.external.pushtoemacsclient-${PV}.jar \
			net.sf.jabref.external.pushtoemacsclient.jar
}