[patch] This is an example patch for the proposal.

rsync-3.0.4-r1.ebuild (text/plain), 3.05 KB, created by Nicholas Fiorentini on 2008-11-07 22:43:31 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
#
# This ebuild of Rsync allow to apply the patches with the use flag
# This in only an example. Not all patches are enabled.
# USE FLAG			APPLYED PATCH
# rsyncpatchdateonly		date-only.diff
# rsyncpatchrenamed		detect-renamed.diff
# rsyncpatchignorecase		ignore-case.diff
# rsyncpatchnameconv		nameconverter.diff
# rsyncpatchtrans		transliterate.diff
# rsyncpatchusermap		usermap.diff
# rsyncpatchdryrun		rsync-3.0.0-dry-run-hang.patch
# 
# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/rsync-3.0.4-r1.ebuild,v 1.1 2008/09/17 09:41:38 vapier Exp $

inherit eutils flag-o-matic toolchain-funcs autotools

DESCRIPTION="File transfer program to keep remote files into sync"
HOMEPAGE="http://rsync.samba.org/"
SRC_URI="http://rsync.samba.org/ftp/rsync/${P/_/}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="acl iconv ipv6 static xattr xinetd rsyncpatchdateonly rsyncpatchrenamed rsyncpatchignorecase rsyncpatchnameconv rsyncpatchtrans rsyncpatchusermap rsyncpatchdryrun"

DEPEND=">=dev-libs/popt-1.5
	acl? ( kernel_linux? ( sys-apps/acl ) )
	xattr? ( kernel_linux? ( sys-apps/attr ) )
	xinetd? ( sys-apps/xinetd )
	iconv? ( virtual/libiconv )"

S=${WORKDIR}/${P/_/}

src_unpack() {
	unpack ${A}
	cd "${S}"

	use rsyncpatchdateonly && epatch "${FILESDIR}"/date-only.diff
	use rsyncpatchrenamed && epatch "${FILESDIR}"/detect-renamed.diff
	use rsyncpatchignorecase && epatch "${FILESDIR}"/ignore-case.diff
	use rsyncpatchnameconv && epatch "${FILESDIR}"/nameconverter.diff
	use rsyncpatchtrans && epatch "${FILESDIR}"/transliterate.diff
#	use rsyncpatchusermap && epatch "${FILESDIR}"/usermap.diff
	use rsyncpatchdryrun && epatch "${FILESDIR}"/rsync-3.0.0-dry-run-hang.patch

}

src_compile() {
	use static && append-ldflags -static
	econf \
		--without-included-popt \
		$(use_enable acl acl-support) \
		$(use_enable xattr xattr-support) \
		$(use_enable ipv6) \
		$(use_enable iconv) \
		--with-rsyncd-conf=/etc/rsyncd.conf \
		|| die
	emake || die "emake failed"
}

pkg_preinst() {
	if [[ -e ${ROOT}/etc/rsync/rsyncd.conf ]] && [[ ! -e ${ROOT}/etc/rsyncd.conf ]] ; then
		mv "${ROOT}"/etc/rsync/rsyncd.conf "${ROOT}"/etc/rsyncd.conf
		rm -f "${ROOT}"/etc/rsync/.keep
		rmdir "${ROOT}"/etc/rsync >& /dev/null
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	newconfd "${FILESDIR}"/rsyncd.conf.d rsyncd
	newinitd "${FILESDIR}"/rsyncd.init.d rsyncd
	dodoc NEWS OLDNEWS README TODO tech_report.tex
	insinto /etc
	doins "${FILESDIR}"/rsyncd.conf

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/rsyncd.logrotate rsyncd

	if use xinetd ; then
		insinto /etc/xinetd.d
		newins "${FILESDIR}"/rsyncd.xinetd rsyncd
	fi
}

pkg_postinst() {
	ewarn "The rsyncd.conf file has been moved for you to /etc/rsyncd.conf"
	echo
	ewarn "Please make sure you do NOT disable the rsync server running"
	ewarn "in a chroot.  Please check /etc/rsyncd.conf and make sure"
	ewarn "it says: use chroot = yes"
}