Initial fceux-2.0.3.ebuild

fceux-2.0.3.ebuild (text/plain), 1.20 KB, created by Denilson Sá Maia on 2008-11-04 18:12:25 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $


# TODO: install gfceux
# (or maybe gfceux will be a separate package)


inherit games
# Probably need to inherit python when installing gfceux

DESCRIPTION="A portable Famicom/NES emulator, an evolution of the original FCE Ultra"
HOMEPAGE="http://fceux.com/"
SRC_URI="mirror://sourceforge/fceultra/${P}.src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="dev-lang/lua
	media-libs/libsdl
	virtual/opengl
	sys-libs/zlib
	dev-util/scons"
RDEPEND="${DEPEND}
	gnome-extra/zenity"
# Note: zenity is "almost" optional. It is possible to compile and run fceux
# without zenity, but file dialogs will not work.

src_unpack() {
	unpack ${A}
	mv fceu ${P}
}

src_compile() {
	scons ${MAKEOPTS}
}

src_install() {
	dodir "${GAMES_BINDIR}"
	dogamesbin bin/fceux || die

	doman documentation/fceux.6 || die
	dodoc AUTHORS changelog.txt TODO-PROJECT
	# NEWS and README files are currently empty

	# Extra documentation
	insinto "/usr/share/doc/${PF}/"
	doins bin/fceux.chm
	# Removing this file before copying documentation dir
	rm documentation/fceux.6
	doins -r documentation

	prepgamesdirs
}