chromium-0.9.13.2.ebuild

chromium-0.9.13.2.ebuild (text/plain), 1.32 KB, created by Tomáš Chvátal (RETIRED) on 2008-08-15 17:09:56 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="Chromium B.S.U. - an arcade game"
HOMEPAGE="http://chromium-bsu.sourceforge.net/"
SRC_URI="mirror://sourceforge/chromium-bsu/${P}.tar.gz"

LICENSE="Artistic"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X glut mixer openal sdl"

DEPEND="sdl? ( media-libs/libsdl )
	openal? ( media-libs/openal )
	mixer? ( media-libs/sdl-mixer )
	glut? ( media-libs/freeglut )
	media-fonts/dejavu
	media-libs/glpng
	>=media-libs/ftgl-2.1.3_rc5
	virtual/opengl
	virtual/glu
	x11-libs/libXmu"
RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e "s:\${exec_prefix}/games:/usr/games/bin:" \
		configure || die "sed configure failed"
}
src_compile() {
	# no egamesconf cause wrong paths are used
	econf \
		--prefix=/usr \
		--bindir=/usr/games/bin \
		--disable-dependency-tracking \
		--with-font-path="/usr/share/fonts/dejavu/DejaVuSerif-Bold.ttf" \
		$(use_with X) \
		$(use_enable glut) \
		$(use_enable mixer sdlmixer) \
		$(use_enable openal) \
		$(use_enable sdl)

	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	newicon data/png/hero.png ${PN}.png
	make_desktop_entry chromium "Chromium B.S.U"
	dodoc AUTHORS README NEWS
	prepgamesdirs
}