# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit eutils toolchain-funcs qt4

DESCRIPTION="Voice chat software for gaming written in Qt4"
HOMEPAGE="http://mumble.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa dbus debug oss portaudio pulseaudio speech"

RDEPEND=">=media-libs/speex-1.2_beta3_p2
	dev-libs/boost
	x11-libs/libXevie
	|| ( ( x11-libs/qt-gui:4
		   x11-libs/qt-opengl:4
		   x11-libs/qt-sql:4
		   dbus? ( x11-libs/qt-dbus:4 ) )
		 ( =x11-libs/qt-4.3*:4 ) )
	alsa? ( media-libs/alsa-lib )
	dbus? ( sys-apps/dbus )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )
	speech? ( app-accessibility/speech-dispatcher )"

DEPEND="${RDEPEND}
	>=sys-devel/gcc-3.4"

QT4_BUILT_WITH_USE_CHECK="ssl sqlite3 dbus"

src_compile() {
	use dbus || conf_add="${conf_add} no-dbus"
	use portaudio || conf_add="${conf_add} no-portaudio"
	use pulseaudio || conf_add="${conf_add} no-pulseaudio"
	use alsa || conf_add="${conf_add} no-alsa"
	use oss || conf_add="${conf_add} no-oss"
	use speech || conf_add="${conf_add} no-speechd"
	use debug || conf_add="${conf_add} release"
	use debug && conf_add="${conf_add} symbols debug"

	eqmake4 "${S}/main.pro" -recursive CONFIG+="${conf_add} no-server no-bundled-speex" DEFINES+="PLUGIN_PATH=/usr/lib/mumble" \
		|| die "eqmake4 failed"
	emake || die "emake failed"
}

src_install() {
	newdoc README.Linux README
	dodoc CHANGES

	local dir
	if use debug; then
		dir=debug
	else
		dir=release
	fi

	dobin ${dir}/mumble	|| die "installing failed"

	CONF_LIBDIR="$(get_libdir)/mumble" dolib.so ${dir}/lib*.so* || die "installing libs failed"
	CONF_LIBDIR="$(get_libdir)/mumble" dolib.so ${dir}/plugins/lib*.so* || die "installing libs failed"

	dobin scripts/mumble-overlay || die "installing overlay failed"
	newicon icons/mumble.64x64.png mumble.png || die "installing icon failed"
	make_desktop_entry ${PN} "Mumble" mumble "Qt;KDE;Network;Telephony;" \
		|| die "installing menu entry failed"

	doman man/mumble-overlay.1
	doman man/mumble.1
	insinto /usr/share/services
	doins scripts/mumble.protocol
}

pkg_postinst() {
	elog
	elog "Visit http://mumble.sourceforge.net/Audio_Tuning for futher configuration"
	elog "type mumble to run the client,"
	elog "type mumble-overlay to start the gaming overlay (after starting mumble)"
}