proposed ebuild

cntlm-0.35.1-r1.ebuild (text/plain), 903 bytes, created by Wojciech Porczyk on 2008-06-18 20:52:20 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Cntlm is an NTLM/NTLMv2 authenticating HTTP proxy"
HOMEPAGE="http://cntlm.sourceforge.net/"
SRC_URI="mirror://sourceforge/cntlm/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=""
RDEPEND=""

pkg_setup() {
	enewgroup cntlm
	enewuser cntlm -1 -1 -1 cntlm
}

src_compile() {
	econf || die "econf failed"
	
	# Replace default config file path in Makefile
	sed -i -e 's~SYSCONFDIR=/usr/local/etc~SYSCONFDIR=/etc~' \
				"${S}"/Makefile || die "sed failed"

	emake || die "emake failed"
}

src_install() {
	dobin cntlm
	dodoc COPYRIGHT LICENSE README VERSION doc/cntlm.conf
	doman doc/cntlm.1
	newinitd ${FILESDIR}/cntlm.initd cntlm
	newconfd ${FILESDIR}/cntlm.confd cntlm
	insinto /etc
	insopts -m0600
	doins doc/cntlm.conf 
}