# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-1.20.ebuild,v 1.1 2008/05/13 02:54:27 compnerd Exp $

inherit autotools eutils

DESCRIPTION="Simple BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com/"
SRC_URI="http://download.transmissionbt.com/transmission/files/${P}.tar.bz2"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="gtk libnotify"

RDEPEND="gtk? ( >=dev-libs/glib-2.16 )
		 >=dev-libs/openssl-0.9.8
		 gtk? ( >=x11-libs/gtk+-2.6 )
		 libnotify? ( >=x11-libs/libnotify-0.4.4 )"
DEPEND="${RDEPEND}
		>=dev-util/pkgconfig-0.19
		gtk? ( >=dev-util/intltool-0.35 )"

src_compile() {
	econf \
		$(use_with gtk) \
		$(use_enable libnotify) \
		--with-wx-config=no || die "configure failed"
	emake || die "build failed"
}

src_install() {
	make DESTDIR="${D}" install || die "install failed"
	dodoc AUTHORS NEWS
	keepdir /var/run/transmission
	fperms 0750 /var/run/transmission
	fowners transmission:transmission /var/run/transmission

	keepdir /var/lib/transmission
	fperms 0770 /var/lib/transmission
	fowners transmission:transmission /var/lib/transmission

	newinitd "${FILESDIR}/transmission-daemon.initd" transmission-daemon
	newconfd "${FILESDIR}/transmission-daemon.confd" transmission-daemon
}

pkg_setup() {
	enewgroup transmission 
	enewuser transmission -1 -1 /var/lib/transmission transmission
}