wulfware-2.6.0.ebuild

wulfware-2.6.0.ebuild (text/plain), 1.08 KB, created by Samuli Suominen (RETIRED) on 2008-05-22 11:02:00 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils multilib toolchain-funcs

DESCRIPTION="Applications to monitor on a beowulf- or GRID-style clusters."
HOMEPAGE="http://www.phy.duke.edu/~rgb/Beowulf/wulfware.php"
SRC_URI="http://www.phy.duke.edu/~rgb/Beowulf/${PN}/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="dev-libs/libxml2
	sys-libs/ncurses
	sys-libs/zlib"
DEPEND="${RDEPEND}
	!sys-cluster/wulfstat
	!sys-cluster/xmlsysd"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-opts_and_strip.patch
	eautoreconf
}

src_compile() {
	export ac_cv_prog_ac_ct_STRIP="true"
	econf --disable-dependency-tracking
	emake -j1 CC=$(tc-getCC) || die "emake failed."
}

src_install() {
	emake prefix="${D}/usr" libdir="${D}/usr/$(get_libdir)" \
		includedir="${D}/usr/include" sysconfdir="${D}/etc" \
		install || die "emake install failed."

	dodoc AUTHORS ChangeLog NEWS NOTES README

	# FIXME: Update to Gentoo style init script.
	rm -rf "${D}"/etc/init.d/wulf2html
}