# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Barry is an Open Source Linux application that will allow
synchronization, backup, restore, program management, and charging for BlackBerry devices"
HOMEPAGE="http://www.netdirect.ca/software/packages/barry/"
SRC_URI="mirror://sourceforge/barry/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="boost gui opensync"

DEPEND="dev-libs/libusb
	dev-libs/openssl
	boost? ( >=dev-libs/boost-1.33  )
	gui? ( >=dev-cpp/gtkmm-2.4
                >=dev-cpp/libglademm-2.4
                >=dev-cpp/glibmm-2.4
                =dev-libs/libtar-1.2.11-r1 )
        opensync? ( =app-pda/libopensync-0.22* )"

src_unpack() {
	unpack ${A}
	cd "${S}/gui/src"
	epatch "${FILESDIR}/${P}-tarfile-int.patch"
}

src_compile(){
	econf \
		$(use_with boost boost=/usr/include) \
		$(use_enable gui) \
		$(use_with gui libtar=/usr/lib) \
		$(use_with gui libz=/usr/lib) \
		$(use_enable opensync opensync-plugin) \
		|| die "Error: econf failed!"
	emake || die "Error: emake failed!"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	dodoc README NEWS

	#  udev rules
	insinto /etc/udev/rules.d
	newins udev/10-blackberry.rules 10-blackberry.rules
}