frobtads-0.10.ebuild

frobtads-0.10.ebuild (text/plain), 1.72 KB, created by Nikos Chantziaras on 2008-04-14 00:38:58 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="Curses-based interpreter and development tools for TADS 2 and TADS 3 text adventures"
HOMEPAGE="http://www.tads.org/frobtads.htm"
SRC_URI="http://www.tads.org/frobtads/${P}.tar.gz
	tads2compiler? ( http://www.tads.org/frobtads/t2comp-${PV}.tar.gz )
	tads3compiler? ( http://www.tads.org/frobtads/t3comp-${PV}.tar.gz )"

LICENSE="TADS"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug tads2compiler tads3compiler"

RESTRICT="!tads3compiler? ( test )"

DEPEND="sys-libs/ncurses"

src_unpack() {
	unpack ${A}
	if use tads2compiler; then
		mv t2compiler/* "${S}"/t2compiler || die "mv t2compiler failed"
	fi
	if use tads3compiler; then
		mv t3compiler/* "${S}"/t3compiler || die "mv t3compiler failed"
	fi
}

src_compile() {
	CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
        # Normally we would just use egamesconf, but it results in a
        # sandbox violation.  See bug 149764.
        # egamesconf $(use_enable debug t3debug) || die "egamesconf failed"
        econf $(use_enable debug t3debug) \
		--bindir=${GAMES_BINDIR} --datadir=${GAMES_DATADIR} \
		 || die "econf failed"
	emake || die "emake failed"
}

src_test() {
	if use debug; then
		emake -j1 check || die "TADS 3 compiler test suite failed"
	fi

	emake -j1 sample || die "Failed to build test game"
	./frob -i plain -p samples/sample.t3 <<- END_FROB_TEST
		save
		testsave.sav
		restore
		testsave.sav
	END_FROB_TEST
	[ $? -eq 0 ] || die "Failed to run test game"
}

src_install() {
	emake DESTDIR="${D}" install || die "Install failed"
	dodoc doc/{AUTHORS,BUGS,ChangeLog,NEWS,README,SRC_GUIDELINES,THANKS} || die "dodoc failed"
	prepgamesdirs
}