# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="Crossover between Quake and Worms."
HOMEPAGE="http://www.teewars.com"
SRC_URI="http://www.${PN}.com/files/${P}-src.tar.gz
	http://www.teewars.com/files/bam.zip
	racemod? ( http://lan-corps.no-ip.org/${PN}/packs/race_mod.rar
		http://oerngott.ugms.se/${PN}/race_mod.rar )"

# see license.txt
LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug racemod server serveronly"

# this should be ok now
DEPEND="!serveronly? (
		media-libs/alsa-lib
		media-libs/mesa
		x11-libs/libX11
		)
	app-arch/zip
	!games-action/teewars-bin"
RDEPEND="${DEPEND}"

SB="${WORKDIR}/bam"
S="${WORKDIR}/${P}-src"

#diropt=${GAMES_PREFIX_OPT}/${PN}
dir="${GAMES_DATADIR}/${PN}"

pkg_setup() {
	if use server && use serveronly; then
		einfo "Can't build with \"server\" and \"serveronly\" USE flags."
		einfo "Disable one of them and restart the merge"
		die "\"server\" and \"serveronly\" USE flags enabled."
	fi
}

src_unpack() {
	unpack ${A}
	cd ${S}

	if use racemod; then
		mv ../"guide to moving.txt" ${S}/guide_to_moving.txt
		mv ../"race mod.txt" ${S}/race_mod.txt
		mv ../*.map ${S}/data/maps/
	fi
}

src_compile() {
	cd ${SB}
	./make_unix.sh || die "make_unix.sh failed"

	cd ${S}

	# start of the dirty part
	sed -i \
		-e "s|flags = \"-Wall\"|flags = \"${CXXFLAGS}\"|" \
		-e "s|linker.flags = \"\"|linker.flags = \"${LDFLAGS}\"|" \
		default.bam || die "sed failed"
	# end

	if use debug && use server; then
		../bam/src/bam -v debug || die "bam failed"
	elif use debug && use serveronly; then
		../bam/src/bam -v server_debug || die "bam failed"
	elif use !debug && use serveronly; then
		../bam/src/bam -v server_release || die "bam failed"
	else
		../bam/src/bam -v release || die "bam failed"
	fi
}

src_install() {
	# if use serveronly, we don't need some garbage
	if use serveronly; then
		insinto "${dir}"/data/maps
		doins data/maps/* || die "doins failed"
	else
		insinto "${dir}"
		doins -r data || die "doins failed"
	fi

	exeinto "${dir}"

	# if use debug, the binary names are different
	if use debug && use server; then
		doexe ${PN}_srv_d || die "doexe ${PN}_srv_d"
		doexe ${PN}_d || die "doexe ${PN}_d"
		games_make_wrapper ${PN}_srv ./${PN}_srv_d "${dir}"
		games_make_wrapper ${PN} ./${PN}_d "${dir}"
		make_desktop_entry ${PN} "Teewars"
	elif use !debug && use server; then
		doexe ${PN}_srv || die "doexe ${PN}_srv"
		doexe ${PN} || die "doexe ${PN}"
		games_make_wrapper ${PN}_srv ./${PN}_srv "${dir}"
		games_make_wrapper ${PN} ./${PN} "${dir}"
		make_desktop_entry ${PN} "Teewars"
	elif use debug && use serveronly; then
		doexe ${PN}_srv_d || die "doexe ${PN}_srv_d"
		games_make_wrapper ${PN}_srv ./${PN}_srv_d "${dir}"
	elif use !debug && use serveronly; then
		doexe ${PN}_srv || die "doexe ${PN}_srv"
		games_make_wrapper ${PN}_srv ./${PN}_srv "${dir}"
	else
		doexe ${PN} || die "doexe ${PN}"
		games_make_wrapper ${PN} ./${PN} "${dir}"
		make_desktop_entry ${PN} "Teewars"
	fi

	dodoc *.txt
}

pkg_postinst() {
	if use server || use serveronly; then
		einfo "For more information about server setup read:"
		einfo "http://www.teewars.com/?page=docs"
	fi

	if use racemod && use server; then
		einfo "Read about server setup for racemod in race_mod.txt"
	fi	
}