# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/squashfs-tools/squashfs-tools-3.3.ebuild,v 1.1 2007/12/30 19:00:03 solar Exp $

inherit eutils toolchain-funcs flag-o-matic

MY_PV=${PV/_p/-r}
DESCRIPTION="Tool for creating compressed filesystem type squashfs"
HOMEPAGE="http://squashfs.sourceforge.net/"
SRC_URI="mirror://sourceforge/squashfs/squashfs${MY_PV}.tar.gz
	lzma? ( http://www.squashfs-lzma.org/dl/lzma449.tar.bz2
			http://www.squashfs-lzma.org/dl/sqlzma3.3-fixed.tar.bz2 )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="lzma debug"

RDEPEND="sys-libs/zlib"

S=${WORKDIR}/squashfs${PV/_p/-r}/squashfs-tools

src_unpack() {
	unpack ${A}
	cd "${S}"
	if use lzma; then
		# Compilation fails with this turned on
		append-ldflags "-Wl,--no-as-needed"
		epatch "${FILESDIR}"/squashfs-tools-3.3-sqlzma2u.patch || die patching failed
		epatch "${FILESDIR}"/squashfs-tools-progress-stderr-lzma.patch || die patching failed
	else
		epatch "${FILESDIR}"/squashfs-tools-3.3-posix.patch || die patching failed
		epatch "${FILESDIR}"/squashfs-tools-progress-stderr.patch || die patching failed
	fi
	sed -i "s:-O2:${CFLAGS}:" Makefile
	if use lzma; then
		cd "${WORKDIR}"
		cp "${FILESDIR}"/Makefile.sqlzma Makefile
		# We can't use epatch or the patch will create directories we don't want
		ebegin "Applying squashfs-tools-3.3-sqlzma1-449.patch"
		patch -s -p1 < "${FILESDIR}"/squashfs-tools-3.3-sqlzma1-449.patch || die patching failed
		eend $?
		sed -i "s:-O2:${CFLAGS}:" C/Compress/Lzma/sqlzma.mk
		sed -i -e "s:g++:g++ ${CXXFLAGS}:" \
			   -e "s:gcc:gcc ${CFLAGS}:" \
			      CPP/7zip/Compress/LZMA_Alone/makefile.gcc
		sed -i "s:-D_REENTRANT:${CXXFLAGS} -D_REENTRANT:" CPP/7zip/Compress/LZMA_Alone/sqlzma.mk
		sed -i -e "s:BuildSquashfs = 1:BuildSquashfs =:" \
			   -e 's:Lzma = ${Sqlzma}/${LzmaVer}:Lzma = ${Sqlzma}:' \
			   -e 's:KDir = /lib/modules/$(shell uname -r)/build::' \
				  Makefile
		if use debug; then
			sed -i 's:UseDebugFlags =:UseDebugFlags = 1:' Makefile
		fi
	fi
}

src_compile() {
	use lzma && cd "${WORKDIR}"
	emake CC="$(tc-getCC)" || die
}

src_install() {
	dobin mksquashfs unsquashfs || die
	cd ..
	dodoc README ACKNOWLEDGEMENTS CHANGES PERFORMANCE.README README-3.3
}