# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-block/open-iscsi/open-iscsi-2.0.865.12.ebuild,v 1.2 2007/08/29 07:11:49 mr_bones_ Exp $

inherit versionator eutils flag-o-matic linux-info

DESCRIPTION="Open-iSCSI project is a high performance, transport independent, multi-platform implementation of RFC3720."
HOMEPAGE="http://www.open-iscsi.org/"
MY_PV="$(replace_version_separator 2 '-')"
MY_P="${PN}-${MY_PV}"
SRC_URI="http://www.open-iscsi.org/bits/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64 ~ppc"
IUSE="debug"
DEPEND="virtual/libc
		virtual/linux-sources"
RDEPEND="${DEPEND}
		sys-apps/util-linux"

CONFIG_CHECK="SCSI_ISCSI_ATTRS ISCSI_TCP"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack "${A}"

	cd "${S}"

	epatch "${FILESDIR}/remove-kernel-and-init-to-makefile.patch"
}

src_compile() {
	use debug && append-flags -DDEBUG_TCP -DDEBUG_SCSI

	einfo "Building userspace"
	emake CC="$(tc-getCC)" OPTFLAGS="" || die "emake failed"
}

src_install() {
	einfo "Installing userspace"
	emake DESTDIR="${D}" install || die "install failed"

	einfo "Installing docs"
	doman doc/*[1-8]
	dodoc README THANKS
	docinto test
	dodoc test/README

	einfo "Installing configuration"
	insinto /etc/iscsi
	doins ${FILESDIR}/initiatorname.iscsi

	newinitd ${FILESDIR}/iscsid-init.d iscsid

	# security
	keepdir /var/db/iscsi
	fperms 700 /var/db/iscsi
	fperms 600 /etc/iscsi/iscsid.conf
}

pkg_postinst() {
	[ -d ${ROOT}/var/db/iscsi ] && chmod 700 ${ROOT}/var/db/iscsi
	[ -f ${ROOT}/etc/iscsi/iscsid.conf ] && chmod 600 ${ROOT}/etc/iscsi/iscsid.conf
}

pkg_config() {
	if [ ! -f /etc/iscsi/initiatorname.iscsi ]; then
		echo "InitiatorName=`/sbin/iscsi-iname`" > /etc/iscsi/initiatorname.iscsi
		echo "***************************************************"
		echo "Setting InitiatorName to `cat /etc/iscsi/initiatorname.iscsi`"
		echo "To override edit /etc/iscsi/initiatorname.iscsi"
		echo "***************************************************"
	fi
}