# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/app-games/emilia-pinball/emilia-pinball-0.1.2-r1.ebuild,v 1.1 2003/03/20 13:00:21 vladimir Exp $

inherit games

MY_PN=${PN/emilia-/}
MY_P=${MY_PN}-${PV}
DESCRIPTION="SDL OpenGL pinball game"
HOMEPAGE="http://pinball.sourceforge.net/"
SRC_URI="mirror://sourceforge/pinball/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ppc"

DEPEND="virtual/opengl
	virtual/x11
	media-libs/libsdl
	media-libs/sdl-image
	media-libs/sdl-mixer"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	export WANT_AUTOCONF_2_5=1
	cd ${S}/libltdl
	autoconf || die
}

src_compile() {
#	cp Makefile.in Makefile.in.old
#	sed -e '/SUBDIRS =.*test/s:test::' \
#		Makefile.in.old > Makefile.in

#		--with-highscore-prefix=
	egamesconf \
		--with-x \
		--with-allegro=no \
		|| die
	make CXXFLAGS="${CXXFLAGS}" || die
}

src_install() {
	dodoc AUTHORS Changelog COPYING INSTALL NEWS README
	make DESTDIR=${D} install || die

	# now lets clean up what the install did
	# yeah its ugly but FHS == good thing
	local sharedir=${GAMES_DATADIR}/${MY_PN}
	local libdir=${GAMES_PREFIX}/lib/${MY_PN}
	rm -rf ${D}/${GAMES_PREFIX}/include
	dodir ${libdir}
	for dir in professor tux ; do
		cd ${D}/${sharedir}/${dir}
		for lib in *.so *.so.0 *.0.0.0 *.a *.la ; do
			mv ${lib} ${D}/${libdir}/
			dosym ${libdir}/${lib} ${sharedir}/${dir}/${lib}
		done
	done

	prepgamesdirs
}