# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/app-games/chromium/chromium-0.9.12-r3.ebuild,v 1.1 2003/06/21 23:52:12 vapier Exp $

inherit games eutils

S=${WORKDIR}/Chromium-0.9
DESCRIPTION="Chromium B.S.U. - an arcade game"
HOMEPAGE="http://www.reptilelabour.com/software/chromium/"
SRC_URI="http://www.reptilelabour.com/software/files/chromium/chromium-src-${PV}.tar.gz
	 http://www.reptilelabour.com/software/files/chromium/chromium-data-${PV}.tar.gz"

SLOT="0"
KEYWORDS="x86 ppc"
LICENSE="Artistic"
IUSE="arts esd qt sdl svga oggvorbis alsa"

DEPEND="virtual/glibc
	sys-devel/gcc
	virtual/glut
	sdl? ( media-libs/libsdl )
	qt? ( =x11-libs/qt-2* )
	oggvorbis? ( media-libs/libogg media-libs/libvorbis )
	media-libs/libggi
	media-libs/libgii
	alsa? ( media-libs/alsa-lib )
	arts? ( kde-base/kdelibs )
	esd? ( media-sound/esound )
	media-libs/audiofile
	svga? ( media-libs/svgalib )
	>=media-libs/smpeg-0.4.4-r1" # this last isn't strictly needed but is useful

src_unpack() {
	unpack ${A}
	epatch ${FILESDIR}/${P}-gcc3-gentoo.patch
}

src_compile() {
	local myconf
	myconf="${myconf} --enable-smpeg"
	myconf="${myconf} `use_enable sdl`"
	myconf="${myconf} `use_enable oggvorbis vorbis`"
	myconf="${myconf} `use_enable qt setup`"

	./configure ${myconf} || die
	QTDIR=/usr/qt/2 make || die
}

src_install() {
	rm -rf `find -name CVS`

	exeinto ${GAMES_BINDIR}
	doexe bin/chromium*

	dodir ${GAMES_DATADIR}/${PN}/doc
	dodir ${GAMES_DATADIR}/${PN}/data
	dodir ${GAMES_DATADIR}/${PN}/data/fonts
	dodir ${GAMES_DATADIR}/${PN}/data/png
	dodir ${GAMES_DATADIR}/${PN}/data/wav
	cp -a data/doc/* ${D}/${GAMES_DATADIR}/${PN}/doc
	cp -a data/fonts/* ${D}/${GAMES_DATADIR}/${PN}/data/fonts
	cp -a data/png/* ${D}/${GAMES_DATADIR}/${PN}/data/png
	cp -a data/wav/* ${D}/${GAMES_DATADIR}/${PN}/data/wav
	#cp -a data/* ${D}/${GAMES_DATADIR}/${PN}/data

	dodir /etc/env.d
	echo "CHROMIUM_DATA=${GAMES_DATADIR}/${PN}/data" > ${D}/etc/env.d/99chromium

	prepgamesdirs
}