media-sound/murmur-1.1.1.ebuild

murmur-1.1.1.ebuild (text/plain), 1.31 KB, created by jon R-B on 2007-12-23 16:17:51 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs

MY_P=mumble-${PV}

DESCRIPTION="voice chat software for gaming written in Qt4 (server)"
HOMEPAGE="http://mumble.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="pch"

DEPEND="=x11-libs/qt-4*"

RDEPEND="${DEPEND}"

S="${WORKDIR}"/${MY_P}

pkg_setup() {
	if ! built_with_use -o =x11-libs/qt-4* sqlite sqlite3 dbus zlib; then
		echo
		ewarn "You need to build Qt4 with DBus, zlib plus the sqlite and/or sqlite3 use flag"
		echo
		die "Your Qt4 has no dbus or zlib or sqlite support"
	fi
	enewgroup murmur
	enewuser murmur -1 -1 /var/lib/murmur murmur
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	use pch || sed -i -e '3s: precompile_header$::' mumble.pri
}

src_compile() {
	cd src/murmur
	qmake murmur.pro 	|| die "qmake failed"
	emake CC="$(tc-getCC) ${CFLAGS}" \
		CXX="$(tc-getCXX) ${CXXFLAGS}" \
		LINK="$(tc-getCXX)" || die "emake failed"
}

src_install() {
	dodoc README CHANGES	|| die "installing docs failed"
	cd release
	dobin murmurd			|| die "installing failed"
	insinto /etc/murmur
	cd ../scripts
	doins murmur.ini
	newinitd "${FILESDIR}"/murmurd.rc murmur
	newconfd "${FILESDIR}"/murmur.confd murmur
}