# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_P=${P//./}

DESCRIPTION="An X Window implementation of the Glk API 0.61"
HOMEPAGE="http://www.eblong.com/zarf/glk"
SRC_URI="http://mirror.ifarchive.org/if-archive/programming/glk/implementations/${MY_P}.tar.Z"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="dev-games/glkloader
	>=media-libs/jpeg-6b-r4
	>=media-libs/libpng-1.2.8
	>=media-libs/libsdl-1.2.7-r2
	>=media-libs/sdl-mixer-1.2.5-r1
	x11-libs/libX11"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# patch from http://www.ifarchive.org/if-archive/programming/glk/implementations/patches/xglk0411-sdl-mixer-sound.tgz
	# by Adam Thornton, fixes a number of issues and adds sound
	epatch "${FILESDIR}"/xglk-sdl-mixer-24bit-sanity.diff
	epatch "${FILESDIR}"/xglk-0.4.11-64bit.patch
	epatch "${FILESDIR}"/xglk-0.4.11-Makefile.patch

	rm glk.h gi_blorb.h gi_dispa.h || die
}

src_compile() {
	emake MULTILIB_LIBDIR="$(get_libdir)" || die
}

src_install() {
	emake DESTDIR="${D}" MULTILIB_LIBDIR="$(get_libdir)" install || die
	dodoc PREFS README TODO || die

	insinto /etc/glkloader.d || die
	newins ${FILESDIR}/0.4.11-xglk.rc xglk.rc || die
	sed -i -e "s,lib,$(get_libdir)," "${D}"/etc/glkloader.d/xglk.rc || die

	insinto /usr/include/glk || die
	doins glkstart.h || die
}