# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$

inherit eutils multilib rpm

IUSE="multilib static"

MY_P="${P/-simplelabeler/Applications}"
DESCRIPTION="LightScribe Simple Labeler by HP (binary only GUI)"
HOMEPAGE="http://www.lightscribe.com/downloadSection/linux/index.aspx"
SRC_URI="http://www.lightscribe.com/downloadSection/linux/downloads/lsl/${MY_P}-linux-2.6-intel.rpm"

RESTRICT="mirror strip"
LICENSE="HP-LightScribe"
SLOT="0"
KEYWORDS="~x86 ~amd64"

DEPEND=""
RDEPEND="virtual/libc
	app-cdr/liblightscribe
	sys-libs/zlib
	x86?  ( >=media-libs/freetype-2.1.10
		media-libs/fontconfig
		media-libs/libpng
		!static? ( =x11-libs/qt-4* )
		x11-libs/libICE
		x11-libs/libSM
		x11-libs/libX11
		x11-libs/libXcursor
		x11-libs/libXext )
	amd64? ( app-emulation/emul-linux-x86-xlibs
		 app-emulation/emul-linux-x86-compat )"
MY_INSDIR="/opt/lightscribe/SimpleLabeler"

pkg_setup() {
	if ! use static && use x86; then
		if ! built_with_use x11-libs/qt qt3support; then
			eerror
			eerror "Qt3support is not enabled in x11-libs/qt-4.x.x!!!"
			eerror
			die "Please rebuild it with USE='qt3support'"
		fi
	fi
}

src_unpack() {
	rpm_src_unpack
}

src_install() {
	has_multilib_profile && ABI="x86"

	exeinto ${MY_INSDIR}
	doexe opt/lightscribeApplications/SimpleLabeler/SimpleLabeler
	doexe opt/lightscribeApplications/SimpleLabeler/launchBrowser.sh
	exeinto ${MY_INSDIR}/plugins/accessible
	doexe opt/lightscribeApplications/SimpleLabeler/plugins/accessible/*.so
	insinto ${MY_INSDIR}
	doins opt/lightscribeApplications/SimpleLabeler/qt.conf
	doins -r opt/lightscribeApplications/SimpleLabeler/content
	dodoc opt/lightscribeApplications/lightscribeLicense.rtf
	dosym ${MY_INSDIR}/SimpleLabeler /usr/bin/${PN}

	if use static || use amd64; then
		into ${MY_INSDIR}
		dolib.so opt/lightscribeApplications/common/Qt/*
		dodir /etc/env.d
		echo "LDPATH=/opt/lightscribe/SimpleLabeler/$(get_libdir)" > ${D}/etc/env.d/80lightscribe-simplelabeler
	fi

	newicon opt/lightscribeApplications/SimpleLabeler/content/images/LabelWizardIcon.png ${PN}.png
	make_desktop_entry lightscribe-simplelabeler "LightScribe Simple Labeler" ${PN}.png DiscBurning

}

pkg_postinst() {
	einfo
	einfo "You might want to have a look at the LightScribe Free Label Gallery at"
	einfo "http://www.lightscribe.com/ideas/labelgallery.aspx?id=219"
	einfo
}