# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mumble/mumble-1.0.0.ebuild,v 1.0 2007/07/16 19:13:10 drizzt Exp $

inherit eutils toolchain-funcs

DESCRIPTION="A client-server based voice chat software for gaming written in Qt4"
HOMEPAGE="http://mumble.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""

DEPEND=">=x11-libs/qt-4.3
	media-libs/alsa-lib
	dev-libs/boost
	x11-libs/libXevie"

RDEPEND="${DEPEND}"

pkg_setup() {
		if ! built_with_use -o =x11-libs/qt-4* sqlite3; then
		echo
		ewarn "You need to build Qt4 with the sqlite3 use-flag"
		echo
		die "Your Qt4 has no sqlite support"
	fi
	if [[ $(gcc-major-version) -eq 3 && $(gcc-minor-version) -lt 4 ]]; then
		ewarn "You need >=sys-devel/gcc-3.4 to compile ${PN}."
		die "System gcc is too old to compile ${PN}."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/mumble-1.1.0-clientonly.patch 
}

src_compile() {
	qmake main.pro 	|| die "qmake failed"
	emake || die "emake failed"
}

src_install() {
	cd ${WORKDIR}/${P}/
	cat README.Linux >> README
	dodoc README CHANGES		|| die "installing docs failed"

	if built_with_use -o =x11-libs/qt-4* debug; then
		echo
		ewarn "Built debug-version because your Qt4 has the debug use-flag enabled."
		dobin debug/mumble		|| die "installing failed"
		dolib debug/lib*  		|| die "installing failed"
	else
		dobin release/mumble		|| die "installing failed"
		dolib release/lib*  		|| die "installing failed"
	fi
	dobin scripts/mumble-overlay	|| die "installing failed"
	insinto /usr/share/pixmaps
	newins ${WORKDIR}/${P}/icons/mumble.png.0 mumble.png \
		|| die "installing icon failed"
	make_desktop_entry mumble "Mumble" mumble.png "KDE;Qt;AudioVideo" \
		|| die "installing desktop entry failed"
}